;
; Events text for The Rise of Rome scenario
; By Microprose, revised by Allard H.S. Höfelt
; For Civilization 2.62 or higher
;

@BEGINEVENTS

@IF
SCENARIOLOADED
@THEN
PLAYCDTRACK
3
DONTPLAYWONDERS
@ENDIF

@IF
NOSCHISM
defender=anybody
@THEN
@ENDIF

@IF
NEGOTIATION
talker=Romans
talkertype=HumanOrComputer
listener=Carthaginians
listenertype=HumanOrComputer
@THEN
@ENDIF

@IF
NEGOTIATION
talker=Carthaginians
talkertype=HumanOrComputer
listener=Romans
listenertype=HumanOrComputer
@THEN
@ENDIF

@IF
CITYTAKEN
city=Rome
attacker=ANYBODY
defender=Romans
@THEN
TEXT
^^Rome has fallen!
^^
^^The Impossible has happened. Italy mourns.
^^All remaining roman legions in Italy haste to Rome.
ENDTEXT
MOVEUNIT
unit=ANYUNIT
owner=Romans
maprect
35,17,55,17,55,58,35,58
moveto
40,28
numbertomove=ALL
JUSTONCE
@ENDIF

@IF
CITYTAKEN
city=Carthage
attacker=ANYBODY
defender=Carthaginians
@THEN
TEXT
^^Carthage is destroyed!
^^Carthago deletus est !
^
^^Roman legions start to plunder this once-glorious city. 500 Gold Pieces are
added to the Roman treasure.
^
^^In addition, Romans have begun to spread salt all over the fertile countryside around Carthage.
Never again Carthage shall be a dangerous power !!!
^^All grassland has been changed into Plains
ENDTEXT
CHANGEMONEY
receiver=Romans
amount=500
JUSTONCE
CHANGETERRAIN
terraintype=1
maprect
37,61,38,62,37,63,36,62
@ENDIF

@IF
CITYTAKEN
city=La Tene
attacker=ANYBODY
defender=Celts
@THEN
TEXT
^^La Tene, capital and center of Celtic culture has fallen!
^^
^^Celtic druids tell the victorious, after a long torture, about a huge diamond mine in the
Northern Alps never discovered before.
ENDTEXT
CREATEUNIT
unit=Diamond Mine
owner=Celts
veteran=no
homecity=none
locations
39,7
39,8
40,7
40,8
0,0
0,0
0,0
0,0
0,0
endlocations
JUSTONCE
@ENDIF

@IF
CITYTAKEN
city=Alexandria
attacker=ANYBODY
defender=ANYBODY
@THEN
TEXT
^^Alexandria, founded by Alexander himself, has fallen!
ENDTEXT
JUSTONCE
@ENDIF

@IF
CITYTAKEN
city=Antioch
attacker=ANYBODY
defender=ANYBODY
@THEN
TEXT
^^Antioch has fallen! Could this indicate the beginning of collapse of the
glorious Seleucid Greeks?
ENDTEXT
JUSTONCE
@ENDIF

@IF
CITYTAKEN
city=Athens
attacker=ANYBODY
defender=ANYBODY
@THEN
TEXT
^^Athens has fallen! The Akropolis has been severely damaged.
^^
^^Some of the greatest Athenian thinkers have assembled for their new enlighted rulers and
discussed about the location of the legendary Atlantis. Finally, its location has been calculated
and made public. It lies somewhere near Gades. Estimations are that a huge amount of trasury
awaits its first finder.
ENDTEXT
CREATEUNIT
unit=Atlantis
owner=TRIGGERDEFENDER
veteran=no
homecity=None
locations
2,60
3,61
4,60
5,61
6,62
7,63
0,0
0,0
0,0
endlocations
JUSTONCE
@ENDIF

@IF
CITYTAKEN
city=Sparta
attacker=ANYBODY
defender=Celts
@THEN
TEXT
^^Sparta has fallen! Its ancient fame has now passed away.
ENDTEXT
JUSTONCE
@ENDIF

@IF
CITYTAKEN
city=Memphis
attacker=ANYBODY
defender=Ptolemaic Greeks
@THEN
TEXT
^^Memphis has been taken !!
^^
^^All survivors assamble at Giza and are ready for the last defence of the Ptolemaic Dynasty.
^^The entire world realizes that if Giza also has fallen, all the rest of the Egyptian empire will also
perish with it.
ENDTEXT
CREATEUNIT
unit=Giza Pyramids
owner=Ptolemaic Greeks
veteran=no
homecity=none
locations
74,74
74,76
74,78
70,74
70,76
70,78
0,0
0,0
0,0
endlocations
JUSTONCE
@ENDIF

@IF
UNITKILLED
unit=Giza Pyramids
attacker=ANYBODY
defender=Ptolemaic Greeks
@THEN
TEXT
^^Giza has fallen !!!
^^
^^The rest of the once-mighty Egyptian Empire collapses.
^^An enourmous amount of plunder has been retrieved from secret chambers in the Pyramids,
pointed by some prisonners.
ENDTEXT
CHANGEMONEY
receiver=TRIGGERATTACKER
amount=638
DESTROYACIVILIZATION
whom=Ptolemaic Greeks
@ENDIF

@IF
UNITKILLED
unit=Diamond Mine
attacker=ANYBODY
defender=Celts
@THEN
TEXT
^^Celtic Diamond Mine in Alps plundered
^^
^^An amount of about 700 Gold pieces in diamonds have been added to the attacker's treasury
ENDTEXT
CHANGEMONEY
receiver=TRIGGERATTACKER
amount=743
@ENDIF

@IF
UNITKILLED
unit=Atlantis
attacker=ANYBODY
defender=ANYBODY
@THEN
TEXT
^^Atlantis has indeed been found !!!
^^
^^Still perfectly intact, it has now been completely plundered. About 850 Gold Pieces have been
found, more than the highest estimations.
ENDTEXT
CHANGEMONEY
receiver=TRIGGERATTACKER
amount=843
@ENDIF

@ENDEVENTS
