@BEGINEVENTS

@IF
NOSCHISM
defender=ANYBODY
@THEN
@ENDIF

@IF
SCENARIOLOADED
@THEN
PLAYCDTRACK
23
@ENDIF

@IF
TURNINTERVAL
interval=1
@THEN
CHANGEMONEY
receiver=Americans
amount=15
@ENDIF

@IF
UNITKILLED
unit=UFO
attacker=ANYBODY
defender=Americans
@THEN
TEXT
The Alien ship has been destroyed.
ENDTEXT
CHANGEMONEY
receiver=TRIGGERATTACKER
amount=2000
PLAYCDTRACK
3
@ENDIF

@IF
RANDOMTURN
denominator=600
@THEN
TEXT
A devestating earthquake hits North America, pushing the west coast into the sea!
ENDTEXT
PLAYWAVEFILE
VOLCANO.WAV
JUSTONCE
CHANGETERRAIN
terraintype=10
maprect
11,29,13,29,13,37,11,37
@ENDIF

@IF
RANDOMTURN
denominator=100
@THEN
TEXT
A small asteroid smacks into the Indian sub-contenent. 300 million are killed.
ENDTEXT
PLAYWAVEFILE
VOLCANO.WAV
JUSTONCE
CHANGETERRAIN
terraintype=10
maprect
70,50,72,50,72,54,70,54
@ENDIF

@IF
RANDOMTURN
denominator=800
@THEN
TEXT
A massave asteroid smacks South America!!! The contenent is devastated and the global climate
changed...
ENDTEXT
PLAYWAVEFILE
VOLCANO.WAV
JUSTONCE
PLAYCDTRACK
2
CHANGETERRAIN
terraintype=10
maprect
21,51,33,51,33,71,21,71
@ENDIF

@IF
RANDOMTURN
denominator=100
@THEN
TEXT
A comet's tail passes near earth and sending its poisonous gasses into Siberia.
ENDTEXT
JUSTONCE
CHANGETERRAIN
terraintype=0
maprect
67,17,83,17,83,29,67,29
@ENDIF

@IF
RANDOMTURN
denominator=200
@THEN
TEXT
A major shift in earth's plates causes the mid-Atlantic ridge to rise above sea level! The intense
hurracanes seice along the eastern US causing a drying out of the contenent. The United States
spends 2000 gold on salt-filters to get the needed water from the ocean. The Sahara desert
shrinks due to the new wind patterns.
ENDTEXT
PLAYWAVEFILE
VOLCANO.WAV
JUSTONCE
CHANGETERRAIN
terraintype=5
maprect
39,31,39,31,39,47,39,47
@ENDIF

@IF
CITYTAKEN
city=Washington
attacker=New European Union
defender=Americans
@THEN
TEXT
After the Roman invasion of Washington, the emperor gives a speech to all survivors.
ENDTEXT
CHANGEMONEY
receiver=New European Union
amount=2000
PLAYWAVEFILE
TALK.WAV
@ENDIF

@IF
TURN
turn=100
@THEN
TEXT
The Aliens have finally contacted us. They favor the European Union and trade one of their ships
in exchange for all the knowledge of Earth history and technology. Rome readys its new Sky
Cruiser for battle.
ENDTEXT
CREATEUNIT
unit=Sky Cruiser
owner=New European Union
veteran=yes
homecity=Rome
locations
54,38
endlocations
PLAYWAVEFILE
TALK2.WAV
@ENDIF

@IF
TURN
turn=7
@THEN
TEXT
A volcano erupts in Spain. A new mountain is formed.
ENDTEXT
PLAYWAVEFILE
VOLCANO.WAV
CHANGETERRAIN
terraintype=5
maprect
47,37,47,37,47,37,47,37
@ENDIF

@IF
TURN
turn=40
@THEN
TEXT
A series of shiftings between the Pacific and Indoasin plates causes scientists to believe a "big
one" will hit.
ENDTEXT
@ENDIF

@IF
TURN
turn=41
@THEN
TEXT
Several large earthquakes (7.3-8.7) hit the coast of China. After it is discovered the Japanese
have caused it, from several timed underwater explosions, and help from the already unstable
Pacific plate. Their intention was to devestate coastal China, but some of their bombs were duds
and the plate only rumbled moderatly.
ENDTEXT
CHANGEMONEY
receiver=New European Union
amount=1000
MAKEAGGRESSION
who=United Asian States
whom=Japanese
@ENDIF

@IF
RANDOMTURN
denominator=20
@THEN
TEXT
During an oil drill in northern Siberia, the camp discovers a large hole. The hole was steep and
dark, and the man finally had to come up from the intence heat. The drill was mysteriously
abandoned and rumors of noise coming from the hole hit the world...
ENDTEXT
CREATEUNIT
unit=Caverns
owner=Russians
veteran=no
homecity=none
locations
76,10
endlocations
JUSTONCE
@ENDIF

@IF
UNITKILLED
unit=Caverns
attacker=ANYBODY
defender=Russians
@THEN
TEXT
A robot probe is lowerd down the hole. It sends back readings that prove the earth is hollow! It
is protected from the magma by a magnetic field and is inhabeted by "Skreech Worms", a huge
worm species that is heat tolerant and feeds on bacteria, and make skreeching noises to attract
others to high food areas. These bacteria, as well as the worms, dont need water to survive.
ENDTEXT
PLAYCDTRACK
3
@ENDIF

@IF
UNITKILLED
unit=Sky Legion
attacker=ANYBODY
defender=New European Union
@THEN
TEXT
A Roman Sky Legion has been destroyed. The plane is salvaged.
ENDTEXT
CHANGEMONEY
receiver=TRIGGERATTACKER
amount=100
@ENDIF

@IF
RANDOMTURN
denominator=200
@THEN
TEXT
A massave volcano blast destroys Hawaii!
ENDTEXT
PLAYWAVEFILE
VOLCANO.WAV
JUSTONCE
CHANGETERRAIN
terraintype=5
maprect
1,43,1,43,1,43,1,43
@ENDIF

@ENDEVENTS
