;   CIV II EVENTS - ANCIENT EMPIRES SERIES #2 (3500 BC)
;   "Seeds of Greatness - The Early Empires" Scenario, v1.1 (5/00)
;   (Minoan Events)
;
;
@BEGINEVENTS

@IF
SCENARIOLOADED
@THEN
PLAYWAVEFILE
ae-3500b.wav
@ENDIF

@IF
SCENARIOLOADED
@THEN
DONTPLAYWONDERS
@ENDIF

@IF
citytaken
city=Hattusas
attacker=anybody
defender=Hittites
@THEN
justonce
text
O how ye mighty have fallen! Once invincible Hattusas
lies sacked and looted!
endtext
changemoney
receiver=TRIGGERATTACKER
amount=500
PLAYWAVEFILE
citysack.wav
@ENDIF

@IF
citytaken
city=Ur
attacker=anybody
defender=Babylonians
@THEN
justonce
text
Behold! "Ur of the Chaldees" has fallen to the enemy!
endtext
changemoney
receiver=TRIGGERATTACKER
amount=500
PLAYWAVEFILE
citysack.wav
@ENDIF

@IF
citytaken
city=Nineveh
attacker=anybody
defender=Assyrians
@THEN
justonce
text
The fires of Nineveh mount up to the skies. A terrible
retribution is visited upon her! 
endtext
changemoney
receiver=TRIGGERATTACKER
amount=500
PLAYWAVEFILE
citysack.wav
@ENDIF

@IF
citytaken
city=Memphis
attacker=anybody
defender=Egyptians
@THEN
justonce
text
Alas, mighty Memphis lies crushed beneath the invader's heel!
endtext
changemoney
receiver=TRIGGERATTACKER
amount=500
PLAYWAVEFILE
citysack.wav
@ENDIF

@IF
citytaken
city=Ecbatana
attacker=anybody
defender=Persians
@THEN
justonce
text
No longer protected by her mountainous redoubt, Ecbatana
feels the sting of the conqueror's lash!
endtext
changemoney
receiver=TRIGGERATTACKER
amount=500
PLAYWAVEFILE
citysack.wav
@ENDIF

@IF
citytaken
city=Mycenae
attacker=anybody
defender=Greeks
@THEN
justonce
text
Sacked and burned, "Golden Mycenae" meets with the fate of Troy!
endtext
changemoney
receiver=TRIGGERATTACKER
amount=500
PLAYWAVEFILE
citysack.wav
@ENDIF

@IF
citytaken
city=Knossos
attacker=anybody
defender=Minoans
@THEN
justonce
text
In the end, the seas prove to be a poor safeguard. Knossos burns!
endtext
changemoney
receiver=TRIGGERATTACKER
amount=500
PLAYWAVEFILE
citysack.wav
@ENDIF

@IF
TURN
turn=148
@THEN
TEXT
^The "Great Bull", Minos, ascends to the throne of Crete.
^Truly, the Minoans now rule the seas!
ENDTEXT
CREATEUNIT
unit=Minos
owner=Minoans
veteran=yes
homecity=none
locations
21,47
22,46
23,47
endlocations
PLAYWAVEFILE
leader.wav
@ENDIF

@IF
TURN
turn=171
@THEN
TEXT
^The great "law-giver", Hammurabi ascends to the throne of Babylon.
^Behold the first of the "Great Kings"!
ENDTEXT
CREATEUNIT
unit=Hammurabi
owner=Babylonians
veteran=yes
homecity=none
locations
143,75
144,72
145,73
endlocations
PLAYWAVEFILE
leader.wav
@ENDIF

@IF
TURN
turn=190
@THEN
TEXT
^A mighty emperor, Mursilis I, claims the throne of Hatti.
^Tremble all ye nations!
ENDTEXT
CREATEUNIT
unit=Mursilis I
owner=Hittites
veteran=yes
homecity=none
locations
75,15
74,14
76,18
endlocations
PLAYWAVEFILE
leader.wav
@ENDIF

@IF
TURN
turn=218
@THEN
TEXT
^The God-King, Ramesses II ascends to the throne of Egypt.
^His chariots shall shake the Earth!
ENDTEXT
CREATEUNIT
unit=Ramesses II
owner=Egyptians
veteran=yes
homecity=none
locations
57,89
56,88
58,90
endlocations
PLAYWAVEFILE
leader.wav
@ENDIF

@IF
TURN
turn=283
@THEN
TEXT
^A great king, Ashurbanipal, ascends to the throne of Assyria.
^His armies shall descend upon ye like locusts!
ENDTEXT
CREATEUNIT
unit=Ashurbanipal
owner=Assyrians
veteran=yes
homecity=none
locations
112,34
113,33
114,32
endlocations
PLAYWAVEFILE
leader.wav
@ENDIF

@IF
TURN
turn=294
@THEN
TEXT
^A mighty warrior, Cyrus II lays claim to the throne of Persia.
^None may withstand his power and wisdom!
ENDTEXT
CREATEUNIT
unit=Cyrus II
owner=Persians
veteran=yes
homecity=none
locations
145,45
146,46
145,47
endlocations
PLAYWAVEFILE
leader.wav
@ENDIF

@IF
TURN
turn=315
@THEN
TEXT
^The great conqueror, Alexander, ascends to the throne of Greece.
^The World lies prostrate before him!
ENDTEXT
CREATEUNIT
unit=Alexander
owner=Greeks
veteran=yes
homecity=none
locations
8,30
8,34
6,32
endlocations
PLAYWAVEFILE
leader.wav
@ENDIF

@IF
UNITKILLED
unit=Mursilis I
attacker=anybody
defender=Hittites
@THEN
TEXT
^Weep ye People of Hatti! Mursilis I has been slain in battle!
^The Hittite Army redeems his body for 500 Gold!
ENDTEXT
changemoney
receiver=TRIGGERATTACKER
amount=500
@ENDIF

@IF
UNITKILLED
unit=Hammurabi
attacker=anybody
defender=Babylonians
@THEN
TEXT
^Tremble O' Babylon! Hammurabi has been slain in battle!
^The victors scavenge 500 Gold from the field of battle!
ENDTEXT
changemoney
receiver=TRIGGERATTACKER
amount=500
@ENDIF

@IF
UNITKILLED
unit=Ashurbanipal
attacker=anybody
defender=Assyrians
@THEN
TEXT
^Woe unto Assyria! Ashurbanipal has been slain in battle!
^The victors ransom his battered corpse for 500 Gold!
ENDTEXT
changemoney
receiver=TRIGGERATTACKER
amount=500
@ENDIF

@IF
UNITKILLED
unit=Ramesses II
attacker=anybody
defender=Egyptians
@THEN
TEXT
^Ramesses II is slain in battle! Who will defend ye now, O Egypt?
^The victors loot 500 Gold from the Egyptian camp!
ENDTEXT
changemoney
receiver=TRIGGERATTACKER
amount=500
@ENDIF

@IF
UNITKILLED
unit=Cyrus II
attacker=anybody
defender=Persians
@THEN
TEXT
^A shudder sweeps across the Persian Empire! Cyrus II has been slain in battle!
^The exultant enemy loot 500 Gold from the battlefield!
ENDTEXT
changemoney
receiver=TRIGGERATTACKER
amount=500
@ENDIF

@IF
UNITKILLED
unit=Alexander
attacker=anybody
defender=Greeks
@THEN
TEXT
^A disaster of incomprehensible magnitude! Alexander has been slain in battle!
^The mournful Greek Army ransoms his body for 500 Gold!
ENDTEXT
changemoney
receiver=TRIGGERATTACKER
amount=500
@ENDIF

@IF
UNITKILLED
unit=Minos
attacker=anybody
defender=Minoans
@THEN
TEXT
^A terrible naval defeat claims the life of Minos of Crete!
^Enemy mariners find 500 Gold aboard his captured flagship!
ENDTEXT
changemoney
receiver=TRIGGERATTACKER
amount=500
@ENDIF

@IF
UNITKILLED
unit=Warriors
attacker=Minoans
defender=Barbarians
@THEN
TEXT
Another town is added to the Minoan Empire! The defeated
survivors are enslaved and sent to till the fields of Knossos.
The King takes 50 gold as his share of the booty!
ENDTEXT
changemoney
receiver=TRIGGERATTACKER
amount=50
CREATEUNIT
unit=Farmers
owner=Minoans
veteran=yes
homecity=none
locations
23,49
21,49
endlocations
@ENDIF

@IF
UNITKILLED
unit=Palace Guard
attacker=Minoans
defender=Barbarians
@THEN
TEXT
A powerful enemy city-state is conquered at last!
The sack adds 100 gold to Minoan coffers,
and the victorious General is promoted to Royal Envoy!
ENDTEXT
changemoney
receiver=TRIGGERATTACKER
amount=100
CREATEUNIT
unit=Royal Envoy
owner=Minoans
veteran=yes
homecity=none
locations
23,49
21,49
endlocations
@ENDIF

@IF
UNITKILLED
unit=Caravan
attacker=Minoans
defender=anybody
@THEN
TEXT
A caravan is destroyed! The attackers pillage 80 gold from the wreckage.
ENDTEXT
changemoney
receiver=TRIGGERATTACKER
amount=80
@ENDIF

@IF
UNITKILLED
unit=Farmers
attacker=Minoans
defender=anybody
@THEN
TEXT
^Foreign peasants are captured by the Minoans. They are enslaved and
^shipped off to Knossos!
ENDTEXT
CREATEUNIT
unit=Farmers
owner=Minoans
veteran=yes
homecity=none
locations
23,49
21,49
endlocations
@ENDIF

@IF
TURN
turn=40
@THEN
TEXT
The earth groans and the people cry out in fear as a great Earthquake
shakes Knossos! The sound is like that of a Monstrous Bull, bellowing
from far beneath the city. Thus begins the legend of the Minotaur!
ENDTEXT
CREATEUNIT
unit=earthquake
owner=barbarians
veteran=false
homecity=none
locations
21,49
20,48
endlocations
@ENDIF

@IF
TURN
turn=42
@THEN
TEXT
King Minos proclaims the Earthquake a warning from the Gods
and orders the construction of a powerful fleet of warships!
ENDTEXT
CREATEUNIT
unit=Trikonter
owner=Minoans
veteran=true
homecity=none
locations
22,46
21,47
endlocations
@ENDIF

@IF
TURN
turn=91
@THEN
TEXT
^Cycladic Pirates raid the Minoan homeland!
ENDTEXT
createunit
owner=Barbarians
unit=Bronze Infantry I
veteran=true
homecity=none
locations
17,47
18,48
19,47
endlocations
@ENDIF
@IF
TURN
turn=91
@THEN
createunit
owner=Barbarians
unit=Skirmishers
veteran=true
homecity=none
locations
18,48
19,47
17,47
endlocations
@ENDIF

@IF
TURN
turn=107
@THEN
TEXT
The merchants of Knossos develop the concept of overseas trade!
ENDTEXT
GIVETECHNOLOGY
technology=84
receiver=Minoans
@ENDIF

@IF
TURN
turn=110
@THEN
TEXT
Minoan merchants discover the rich land of Egypt!
ENDTEXT
CREATEUNIT
unit=Early Sail
owner=Minoans
veteran=true
homecity=Knossos
locations
48,76
49,75
endlocations
@ENDIF
@IF
TURN
turn=110
@THEN
CREATEUNIT
unit=Caravan
owner=Minoans
veteran=true
homecity=none
locations
48,76
49,75
endlocations
@ENDIF

@IF
TURN
turn=130
@THEN
TEXT
Minos sends a ship laden with merchants and explorers to the far eastern
shore of the Great Sea. There are rumors of fabulous cities and ancient
civilizations far to the southeast in the fabled "Land between the Rivers".
ENDTEXT
CREATEUNIT
unit=Bronze Infantry I
owner=Minoans
veteran=true
homecity=none
locations
82,36
83,37
endlocations
@ENDIF
@IF
TURN
turn=130
@THEN
CREATEUNIT
unit=Caravan
owner=Minoans
veteran=true
homecity=Knossos
locations
82,36
83,37
endlocations
@ENDIF
@IF
TURN
turn=130
@THEN
CREATEUNIT
unit=Early Sail
owner=Minoans
veteran=true
homecity=none
locations
81,37
80,38
endlocations
@ENDIF

@IF
TURN
turn=151
@THEN
TEXT
^Cycladic Pirates raid the Minoan homeland!
ENDTEXT
createunit
owner=Barbarians
unit=Bronze Infantry II
veteran=true
homecity=none
locations
25,49
26,50
26,48
endlocations
@ENDIF
@IF
TURN
turn=151
@THEN
createunit
owner=Barbarians
unit=Bronze Infantry II
veteran=true
homecity=none
locations
25,49
26,50
26,48
endlocations
@ENDIF
@IF
TURN
turn=151
@THEN
createunit
owner=Barbarians
unit=Bronze Infantry II
veteran=true
homecity=none
locations
25,49
26,50
26,48
endlocations
@ENDIF

@IF
TURN
turn=175
@THEN
TEXT
^The earth shakes violently as a great Earthquake topples the Palace at Knossos!
ENDTEXT
CREATEUNIT
unit=earthquake
owner=barbarians
veteran=true
homecity=none
locations
22,50
20,48
endlocations
@ENDIF

@IF
TURN
turn=180
@THEN
TEXT
Blown off course and shipwrecked, Minoan settlers find themselves in a strange
new land. Was it bad luck or could this be the legendary Isle of Copper?
ENDTEXT
CREATEUNIT
unit=Farmers
owner=Minoans
veteran=true
homecity=Knossos
locations
64,48
64,50
endlocations
@ENDIF

@IF
TURN
turn=199
@THEN
TEXT
^The quiet mountain near Akrotiri has awakened from the sleep of millenia.
^The rumbling and venting of steam disquiet many in the population. A small
^group gather their possessions and leave to colonize another island.
ENDTEXT
CREATEUNIT
unit=Farmers
owner=Minoans
veteran=yes
homecity=Akrotiri
locations
25,11
26,38
endlocations
@ENDIF

@IF
TURN
turn=200
@THEN
TEXT
^The Theran volcano erupts, destroying the city of Akrotiri!
ENDTEXT
CHANGETERRAIN
terraintype=9
maprect
30,40,30,40,30,40,30,40
PLAYWAVEFILE
volcano.wav
@ENDIF
@IF
TURN
turn=200
@THEN
CHANGETERRAIN
terraintype=10
maprect
29,41,29,41,29,41,29,41
@ENDIF

@IF
TURN
turn=201
@THEN
TEXT
^Spawn of the volcano, a mighty storm sweeps in and strikes Knossos! 
^Accompanying the wind and water, ash from the Theran eruption begins 
^to rain down on Crete and Egypt. Once productive farmland is buried
^under the ashfall!
ENDTEXT
CREATEUNIT
unit=storm
owner=barbarians
veteran=false
homecity=none
locations
23,49
20,48
22,50
endlocations
CHANGETERRAIN
terraintype=7
maprect
24,48,24,48,24,48,24,48
@ENDIF
@IF
TURN
turn=201
@THEN
CHANGETERRAIN
terraintype=7
maprect
22,50,22,50,22,50,22,50
@ENDIF
@IF
TURN
turn=201
@THEN
CHANGETERRAIN
terraintype=7
maprect
29,35,29,35,29,35,29,35
@ENDIF
@IF
TURN
turn=201
@THEN
CHANGETERRAIN
terraintype=7
maprect
33,47,33,47,33,47,33,47
@ENDIF
@IF
TURN
turn=201
@THEN
CHANGETERRAIN
terraintype=7
maprect
34,40,34,40,34,40,34,40
@ENDIF

@IF
TURN
turn=211
@THEN
TEXT
^Inspired by tales of legendary wealth, the Mycenaean King invades Crete!
^A large Greek army begins the siege of Knossos!
ENDTEXT
makeaggression
who=Greeks
whom=Minoans
createunit
owner=Greeks
unit=Iron Infantry I
veteran=true
homecity=none
locations
20,48
23,49
21,49
endlocations
@ENDIF
@IF
Turn
turn=211
@THEN
makeaggression
who=Minoans
whom=Greeks
@ENDIF
@IF
TURN
turn=211
@THEN
createunit
owner=Greeks
unit=Iron Infantry II
veteran=true
homecity=none
locations
20,48
23,49
21,49
endlocations
@ENDIF
@IF
TURN
turn=211
@THEN
createunit
owner=Greeks
unit=Bronze Infantry II
veteran=true
homecity=none
locations
20,48
23,49
21,49
endlocations
@ENDIF
@IF
TURN
turn=211
@THEN
createunit
owner=Greeks
unit=Armored Tower
veteran=true
homecity=none
locations
20,48
23,49
21,49
endlocations
@ENDIF

@IF
TURN
turn=220
@THEN
TEXT
^Several generations have passed since the volcano on
^Thera erupted. Those areas most affected by the ashfall
^have now become enormously fertile crop-growing regions!
^The devastated forests of the Aegean will take longer 
^to recover.
ENDTEXT
CHANGETERRAIN
terraintype=2
maprect
24,48,24,48,24,48,24,48
@ENDIF
@IF
TURN
turn=220
@THEN
CHANGETERRAIN
terraintype=2
maprect
22,50,22,50,22,50,22,50
@ENDIF
@IF
TURN
turn=240
@THEN
CHANGETERRAIN
terraintype=3
maprect
29,35,29,35,29,35,29,35
@ENDIF
@IF
TURN
turn=240
@THEN
CHANGETERRAIN
terraintype=3
maprect
33,47,33,47,33,47,33,47
@ENDIF
@IF
TURN
turn=240
@THEN
CHANGETERRAIN
terraintype=3
maprect
34,40,34,40,34,40,34,40
@ENDIF

@IF
TURN
turn=230
@THEN
TEXT
^Turmoil convulses the Ancient World! Seemingly from nowhere, the Sea Peoples
^descend in a massive invasion at many points along the Mediterranean coast!
ENDTEXT
createunit
owner=Barbarians
unit=Sea Peoples
veteran=true
homecity=none
locations
17,49
18,48
endlocations
@ENDIF
@IF
TURN
turn=230
@THEN
createunit
owner=Barbarians
unit=Sea Peoples
veteran=true
homecity=none
locations
17,49
18,48
endlocations
@ENDIF
@IF
TURN
turn=230
@THEN
createunit
owner=Barbarians
unit=Sea Peoples
veteran=true
homecity=none
locations
32,22
33,19
endlocations
@ENDIF
@IF
TURN
turn=230
@THEN
createunit
owner=Barbarians
unit=Sea Peoples
veteran=true
homecity=none
locations
3,35
5,35
endlocations
@ENDIF
@IF
TURN
turn=230
@THEN
createunit
owner=Barbarians
unit=Sea Peoples
veteran=true
homecity=none
locations
34,32
36,32
endlocations
@ENDIF

@IF
TURN
turn=290
@THEN
TEXT
^Long tempted by the wealthy Minoan cities on the Anatolian
^coast, the Phrygian's finally strike! A large Chariot army
^surges west toward the Aegean shore!
ENDTEXT
createunit
owner=Barbarians
unit=Chariot IV
veteran=true
homecity=none
locations
48,18
47,19
47,23
endlocations
MOVEUNIT
unit=AnyUnit
owner=Barbarians
maprect
36,12,50,12,50,32,36,32
moveto
31,21
numbertomove=ALL
@ENDIF
@IF
TURN
turn=290
@THEN
createunit
owner=Barbarians
unit=Chariot IV
veteran=true
homecity=none
locations
48,18
47,19
47,23
endlocations
@ENDIF
@IF
TURN
turn=290
@THEN
createunit
owner=Barbarians
unit=Chariot IV
veteran=true
homecity=none
locations
48,18
47,19
47,23
endlocations
@ENDIF
@IF
TURN
turn=291
@THEN
MOVEUNIT
unit=AnyUnit
owner=Barbarians
maprect
36,12,50,12,50,32,36,32
moveto
31,21
numbertomove=ALL
@ENDIF
@IF
TURN
turn=292
@THEN
MOVEUNIT
unit=AnyUnit
owner=Barbarians
maprect
36,12,50,12,50,32,36,32
moveto
31,21
numbertomove=ALL
@ENDIF

@IF
TURN
turn=300
@THEN
TEXT
Silver has been discovered at Mt. Laurion on the Greek mainland!
Any nearby city shall grow wealthy indeed!
ENDTEXT
CHANGETERRAIN
terraintype=9
maprect
15,33,15,33,15,33,15,33
PLAYWAVEFILE
leader.wav
@ENDIF

@IF
RANDOMTURN
denominator=150
@THEN
TEXT
^The skies darken and suddenly a huge storm sweeps in from the Mediterranean!
ENDTEXT
CREATEUNIT
unit=storm
owner=barbarians
veteran=false
homecity=none
locations
34,24
34,30
33,15
endlocations
PLAYWAVEFILE
storm.wav
@ENDIF

@IF
citytaken
city=Mycenae
attacker=Minoans
defender=Greeks
@THEN
justonce
text
^Minos rejoices! The Sack of Mycenae provides sweet revenge
^and gold for his coffers. The victorious General is promoted
^to Royal Envoy and showered with gifts back home at Knossos!
endtext
changemoney
receiver=TRIGGERATTACKER
amount=500
CREATEUNIT
unit=Royal Envoy
owner=minoans
veteran=yes
homecity=none
locations
23,49
21,49
endlocations
PLAYWAVEFILE
citysack.wav
@ENDIF

@IF
TURN
turn=10
@THEN
CREATEUNIT
unit=Farmers
owner=Persians
veteran=true
homecity=none
locations
166,44
164,44
endlocations
@ENDIF

@ENDEVENTS