@BEGINEVENTS

@IF
SCENARIOLOADED
@THEN
DONTPLAYWONDERS
@ENDIF

@IF
NEGOTIATION
talker=Navarrese
talkertype=humanorcomputer
listener=Castillians
listenertype=humanorcomputer
@THEN
@ENDIF

@IF
NEGOTIATION
talker=Castillians
talkertype=humanorcomputer
listener=Navarrese
listenertype=humanorcomputer
@THEN
@ENDIF

@IF
UNITKILLED
unit=Village
attacker=ANYBODY
defender=ANYBODY
@THEN
TEXT
The soldiers ruthlessly plunder the peasants' poor possessions and another village goes up in 
flames!
ENDTEXT
CHANGEMONEY
receiver=TRIGGERATTACKER
amount=150
@ENDIF

@IF
UNITKILLED
unit=Village
attacker=ANYBODY
defender=ANYBODY
@THEN
CHANGEMONEY
receiver=TRIGGERDEFENDER
amount=-50
@ENDIF

@IF
RANDOMTURN
denominator=50
@THEN
TEXT
The Plantagenets restate their claim to the French Crown...
ENDTEXT
MAKEAGGRESSION
who=English
whom=French
@ENDIF

@IF
RANDOMTURN
denominator=50
@THEN
TEXT
The French King once again repudiates the claims of the English in France...
ENDTEXT
MAKEAGGRESSION
who=French
whom=English
@ENDIF

@IF
UNITKILLED
unit=French King
attacker=ANYBODY
defender=ANYBODY
@THEN
CHANGEMONEY
receiver=TRIGGERATTACKER
amount=3000
@ENDIF

@IF
UNITKILLED
unit=French King
attacker=ANYBODY
defender=ANYBODY
@THEN
TEXT
The French King is captured in battle! France is scoured to pay the huge ramson demanded. The 
King's son, the Dauphin, takes command of the Royal Armies.
ENDTEXT
CHANGEMONEY
receiver=French
amount=-2000
@ENDIF

@IF
UNITKILLED
unit=French King
attacker=ANYBODY
defender=ANYBODY
@THEN
CREATEUNIT
unit=Dauphin
owner=French
veteran=no
homecity=Paris
locations
60,52
58,56
67,73
65,47
62,84
endlocations
@ENDIF

@IF
UNITKILLED
unit=English King
attacker=ANYBODY
defender=ANYBODY
@THEN
CHANGEMONEY
receiver=TRIGGERATTACKER
amount=1500
@ENDIF

@IF
UNITKILLED
unit=English King
attacker=ANYBODY
defender=ANYBODY
@THEN
CHANGEMONEY
receiver=English
amount=-1000
@ENDIF

@IF
UNITKILLED
unit=English King
attacker=ANYBODY
defender=ANYBODY
@THEN
TEXT
The English King is captured! The Lords and Commons both contribute to the large ransom 
demanded for his return to freedom. Meanwhile, The Black Price takes up the reins of power. 
ENDTEXT
CREATEUNIT
unit=Black Prince
owner=English
veteran=yes
homecity=London
locations
50,30
46,74
42,32
30,26
endlocations
@ENDIF

@IF
UNITKILLED
unit=Duke
attacker=ANYBODY
defender=ANYBODY
@THEN
CHANGEMONEY
receiver=TRIGGERATTACKER
amount=750
@ENDIF

@IF
UNITKILLED
unit=Duke
attacker=ANYBODY
defender=ANYBODY
@THEN
TEXT
The Duke is captured and a hefty ransom paid!
ENDTEXT
CHANGEMONEY
receiver=TRIGGERDEFENDER
amount=-500
@ENDIF

@IF
UNITKILLED
unit=Joan of Arc
attacker=ANYBODY
defender=ANYBODY
@THEN
TEXT
The Maid of Orleans is captured - and burnt as a witch! French morale slumps alarmingly, as their 
enemies rejoice. 
ENDTEXT
@ENDIF

@IF
UNITKILLED
unit=Nobility
attacker=ANYBODY
defender=ANYBODY
@THEN
TEXT
Some of the captured Nobility are ransomed - on the undertaking never to bear arms against their 
captors so long as they shall live.
ENDTEXT
CHANGEMONEY
receiver=TRIGGERATTACKER
amount=50
@ENDIF

@IF
TURN
turn=1
@THEN
TEXT
Phillip de Valois tries to confiscate English lands in Gascony. The Gascons rebel and the two 
kingdoms slowly gear up for war.
^^
Grateful thanks to those who have assisted with various aspects of this scenario.
Principally, David Morovan, Philip Benz, Jesùs Balsinde, Yann Dubois and Michael Daumen. Full game credits available from my site at http://www.users.globalnet.co.uk/~netdesign/100years.htm
ENDTEXT
@ENDIF

@IF
TURN
turn=4
@THEN
TEXT
Edward the Third of England publicly assumes the arms of France, quartering the golden lilies on 
their blue ground, with the golden lions of the Plantagenets, and styles himself for the first time 
King of France. The French Nobility ride to war to avenge the insult to Phillip.
ENDTEXT
MAKEAGGRESSION
who=English
whom=French
@ENDIF

@IF
TURN
turn=39
@THEN
TEXT
May 1376: Schismatic Cardinals, influenced heavily by the French Monarchy, elect Clement VII 
as Pope. Half the Christian world supports this new Pope, the other half supports Pope Urban in 
Rome - including the English, of course! However, not wanting to be excommunicated by either 
Pope, the Monarchs of Europe have to tolerate the Papal Envoys of "the French Pope", who are 
trying to further the policies of their master in Paris.
ENDTEXT
GIVETECHNOLOGY
receiver=French
technology=72
@ENDIF

@IF
TURN
turn=35
@THEN
TEXT
Navarrese acquire Early Cannon by bribing gunsmiths from around the world to move to 
Pamplona!
ENDTEXT
CHANGEMONEY
receiver=Navarrese
amount=-400
GIVETECHNOLOGY
receiver=Navarrese
technology=4
@ENDIF

@IF
UNITKILLED
unit=Dauphin
attacker=ANYBODY
defender=ANYBODY
@THEN
TEXT
The Dauphin, too, is captured! Although not as expensive to ransom as his father, the additional 
strain on the French Treasury is acute. The King's brother, the Duke of Orleans, takes over 
command of the French armies in the field. 
ENDTEXT
CHANGEMONEY
receiver=TRIGGERATTACKER
amount=2000
@ENDIF

@IF
UNITKILLED
unit=Dauphin
attacker=ANYBODY
defender=ANYBODY
@THEN
CREATEUNIT
unit=Duke
owner=French
veteran=no
homecity=Orleans
locations
58,56
54,56
60,52
65,47
52,46
endlocations
CHANGEMONEY
receiver=French
amount=-1500
@ENDIF

@IF
UNITKILLED
unit=Black Prince
attacker=ANYBODY
defender=ANYBODY
@THEN
TEXT
Edward, popularly known as the Black Prince from the colour of his favourite armour and one of 
England's best soldiers, is captured. An England already beggared by his father's ransom is 
obliged to raise yet more money. The Duke of Gloucester takes over the reins of power whilst his 
nephew is in captivity - and is reluctant to release them to anyone!
ENDTEXT
CHANGEMONEY
receiver=TRIGGERATTACKER
amount=1000
@ENDIF

@IF
UNITKILLED
unit=Black Prince
attacker=ANYBODY
defender=ANYBODY
@THEN
CREATEUNIT
unit=Duke
owner=English
veteran=no
homecity=London
locations
42,32
50,30
46,20
41,21
endlocations
CHANGEMONEY
receiver=English
amount=-750
@ENDIF

@IF
UNITKILLED
unit=Pedro the Cruel
attacker=ANYBODY
defender=ANYBODY
@THEN
TEXT
Pedro the Cruel is killed! He is not extensively mourned....The Duke of Leon assumes command.
ENDTEXT
CREATEUNIT
unit=Duke
owner=Castillians
veteran=no
homecity=Leon
locations
25,95
33,97
14,88
endlocations
@ENDIF

@IF
UNITKILLED
unit=Charles the Bad
attacker=ANYBODY
defender=ANYBODY
@THEN
TEXT
The morally elastic Charles of Navarre (known to history as "The Bad") finally runs out of luck. 
Being childless, the succession falls to his brother, the Duke.
ENDTEXT
CREATEUNIT
unit=Duke
owner=Navarrese
veteran=no
homecity=Pamplona
locations
40,90
36,92
44,96
44,86
endlocations
@ENDIF

@IF
TURN
turn=75
@THEN
TEXT
The Flemish develop new machinery to produce cloth. These improved - and cheaper - textiles 
are in great demand throughout Europe and give an immense boost to Flemish industry.
ENDTEXT
GIVETECHNOLOGY
receiver=Flemish
technology=80
@ENDIF

@IF
TURN
turn=11
@THEN
TEXT
A dreadful new disease appears in and around the ports of Southern France. Thousands begin to 
sicken...
ENDTEXT
CREATEUNIT
unit=Black Death
owner=Independents
veteran=no
homecity=Marseilles
locations
61,87
58,86
60,88
endlocations
@ENDIF

@IF
TURN
turn=12
@THEN
TEXT
The terrible contagion spreads north and west! Most large cities seem to be affected.
ENDTEXT
CREATEUNIT
unit=Black Death
owner=Independents
veteran=no
homecity=Avignon
locations
63,85
62,86
64,84
endlocations
@ENDIF

@IF
TURN
turn=12
@THEN
CREATEUNIT
unit=Black Death
owner=Independents
veteran=no
homecity=Lyons
locations
68,72
66,74
65,73
endlocations
@ENDIF

@IF
TURN
turn=12
@THEN
CREATEUNIT
unit=Black Death
owner=Independents
veteran=no
homecity=Toulouse
locations
53,83
50,82
49,81
endlocations
@ENDIF

@IF
TURN
turn=12
@THEN
CREATEUNIT
unit=Black Death
owner=Independents
veteran=no
homecity=Bordeaux
locations
45,73
48,74
47,75
endlocations
@ENDIF

@IF
TURN
turn=12
@THEN
CREATEUNIT
unit=Black Death
owner=Independents
veteran=no
homecity=Saumur
locations
46,56
46,58
47,55
endlocations
@ENDIF

@IF
TURN
turn=12
@THEN
CREATEUNIT
unit=Black Death
owner=Independents
veteran=no
homecity=Rouen
locations
51,47
50,46
54,46
endlocations
@ENDIF

@IF
TURN
turn=12
@THEN
CREATEUNIT
unit=Black Death
owner=Independents
veteran=no
homecity=Paris
locations
61,53
59,53
58,52
endlocations
@ENDIF

@IF
TURN
turn=12
@THEN
CREATEUNIT
unit=Black Death
owner=Independents
veteran=no
homecity=Riems
locations
64,48
66,46
67,47
endlocations
@ENDIF

@IF
TURN
turn=12
@THEN
CREATEUNIT
unit=Black Death
owner=Independents
veteran=no
homecity=Dijon
locations
70,60
73,59
72,60
endlocations
@ENDIF

@IF
TURN
turn=12
@THEN
CREATEUNIT
unit=Black Death
owner=Independents
veteran=no
homecity=Brugge
locations
65,33
65,35
64,34
endlocations
@ENDIF

@IF
TURN
turn=13
@THEN
TEXT
The Plague crosses the Channel and spreads west across
the Pyrenees!
ENDTEXT
CREATEUNIT
unit=Black Death
owner=Independents
veteran=no
homecity=London
locations
50,32
48,30
51,29
50,28
endlocations
@ENDIF

@IF
TURN
turn=13
@THEN
CREATEUNIT
unit=Black Death
owner=Independents
veteran=no
homecity=Gloucester
locations
41,31
44,32
endlocations
@ENDIF

@IF
TURN
turn=13
@THEN
CREATEUNIT
unit=Black Death
owner=Independents
veteran=no
homecity=Exeter
locations
38,38
41,37
endlocations
@ENDIF

@IF
TURN
turn=13
@THEN
CREATEUNIT
unit=Black Death
owner=Independents
veteran=no
homecity=York
locations
46,22
48,24
46,18
endlocations
@ENDIF

@IF
TURN
turn=13
@THEN
CREATEUNIT
unit=Black Death
owner=Independents
veteran=no
homecity=Pamplona
locations
38,90
40,88
endlocations
@ENDIF

@IF
TURN
turn=13
@THEN
CREATEUNIT
unit=Black Death
owner=Independents
veteran=no
homecity=Burgos
locations
33,99
32,96
endlocations
@ENDIF

@IF
TURN
turn=13
@THEN
CREATEUNIT
unit=Black Death
owner=Independents
veteran=no
homecity=Leon
locations
23,95
26,94
endlocations
@ENDIF

@IF
TURN
turn=13
@THEN
CREATEUNIT
unit=Black Death
owner=Independents
veteran=no
homecity=Lancaster
locations
42,20
43,23
46,28
endlocations
@ENDIF

@IF
TURN
turn=13
@THEN
CREATEUNIT
unit=Black Death
owner=Independents
veteran=no
homecity=Brugge
locations
61,39
60,40
endlocations
@ENDIF

@IF
TURN
turn=14
@THEN
TEXT
Scotland, Ireland and the furthest reaches of Europe
succumb to the dreadful disease... 
ENDTEXT
CREATEUNIT
unit=Black Death
owner=Independents
veteran=no
homecity=Edinburgh
locations
44,8
41,9
41,15
41,7
43,15
endlocations
@ENDIF

@IF
TURN
turn=14
@THEN
CREATEUNIT
unit=Black Death
owner=Independents
veteran=no
homecity=Dublin
locations
30,24
28,26
endlocations
@ENDIF

@IF
TURN
turn=14
@THEN
CREATEUNIT
unit=Black Death
owner=Independents
veteran=no
homecity=Cork
locations
23,33
24,30
endlocations
@ENDIF

@IF
TURN
turn=14
@THEN
CREATEUNIT
unit=Black Death
owner=Independents
veteran=no
homecity=Santiago
locations
14,86
16,88
endlocations
@ENDIF

@IF
TURN
turn=25
@THEN
TEXT
Plague flares up again near Cahors, in Guyenne! 
ENDTEXT
CREATEUNIT
unit=Black Death
owner=Independents
veteran=no
homecity=Cahors
locations
56,74
54,72
53,75
endlocations
@ENDIF

@IF
RANDOMTURN
denominator=50
@THEN
CREATEUNIT
unit=Merchant
owner=Scots
veteran=no
homecity=York
locations
42,14
endlocations
@ENDIF

@IF
RANDOMTURN
denominator=50
@THEN
CREATEUNIT
unit=Merchant
owner=English
veteran=no
homecity=London
locations
50,30
endlocations
@ENDIF

@IF
RANDOMTURN
denominator=50
@THEN
CREATEUNIT
unit=Merchant
owner=French
veteran=no
homecity=Paris
locations
60,52
endlocations
@ENDIF

@IF
RANDOMTURN
denominator=50
@THEN
CREATEUNIT
unit=Merchant
owner=Castillians
veteran=no
homecity=Burgos
locations
33,97
endlocations
@ENDIF

@IF
RANDOMTURN
denominator=50
@THEN
CREATEUNIT
unit=Merchant
owner=Burgundians
veteran=no
homecity=Dijon
locations
71,59
endlocations
@ENDIF

@IF
RANDOMTURN
denominator=50
@THEN
CREATEUNIT
unit=Merchant
owner=Navarrese
veteran=no
homecity=Pamplona
locations
40,90
endlocations
@ENDIF

@IF
RANDOMTURN
denominator=50
@THEN
CREATEUNIT
unit=Merchant
owner=Flemish
veteran=no
homecity=Ghent
locations
66,34
endlocations
@ENDIF

@IF
RANDOMTURN
denominator=20
@THEN
TEXT
Renegade knights plunder the border between France and Brittany! 
ENDTEXT
CREATEUNIT
unit=Raiders
owner=Independents
veteran=yes
homecity=Rennes
locations
43,59
45,51
44,56
50,50
endlocations
@ENDIF

@IF
RANDOMTURN
denominator=17
@THEN
TEXT
Renegade knights plunder the war-torn lands of Guyenne! 
ENDTEXT
CREATEUNIT
unit=Raiders
owner=Independents
veteran=yes
homecity=Rennes
locations
51,69
49,73
45,65
49,79
endlocations
@ENDIF

@IF
TURN
turn=91
@THEN
TEXT
1428: Near Orleans, a young peasant girl claims to have been given a mission from God to rid 
France of the English. Soon, whether through faith or a cynical desire to use any weapon against 
the ruthless Plantagenets, the French armies unite behind the Maid of Orleans, known to history 
as Joan of Arc.
ENDTEXT
CREATEUNIT
unit=Joan of Arc
owner=French
veteran=no
homecity=Orleans
locations
56,56
55,59
56,58
58,54
60,54
60,54
60,58
61,55
endlocations
@ENDIF

@IF
TURNINTERVAL
interval=40
@THEN
TEXT
French raiders strike the south coast of England!
ENDTEXT
CREATEUNIT
unit=Raiders
owner=French
veteran=yes
homecity=Paris
locations
54,34
45,37
47,35
endlocations
MAKEAGGRESSION
who=French
whom=English
@ENDIF

@IF
TURN
turn=8
@THEN
TEXT
1344: Phillip IV makes his son Crown Prince Phillip Duke of Orleans.
ENDTEXT
CREATEUNIT
unit=Duke
owner=French
veteran=no
homecity=Orleans
locations
58,56
endlocations
@ENDIF

@IF
TURN
turn=9
@THEN
TEXT
1345: The Florentine banking houses of Bardi and Peruzzi are forced into bankruptcy 
(due to loaning King Edward III 400 million ducats, upon which he defaulted.)
ENDTEXT
@ENDIF

@IF
TURN
turn=44
@THEN
TEXT
1381: The Peasants Revolt! Driven to desperate measures by the heavy taxes inflicted to pay for 
the wars, the peasants of Essex, led by Wat Tyler, take up arms against their King.
ENDTEXT
CREATEUNIT
unit=Armed Peasants
owner=Independents
veteran=no
homecity=London
locations
51,29
52,28
51,27
53,27
endlocations
@ENDIF

@IF
TURN
turn=44
@THEN
CREATEUNIT
unit=Armed Peasants
owner=Independents
veteran=no
homecity=London
locations
52,28
51,29
51,27
53,27
endlocations
@ENDIF

@IF
TURN
turn=81
@THEN
TEXT
1417: Pope Martin V is elected, heralding the end of the Great Schism. French domination of papal 
affairs is ended - ending their great diplomatic advantage. 
ENDTEXT
GIVETECHNOLOGY
receiver=French
technology=47
@ENDIF

@IF
UNITKILLED
unit=Scottish King
attacker=ANYBODY
defender=ANYBODY
@THEN
TEXT
The Scottish King is killed! The Scottish nation is thrown into confusion, with many rival claimants 
contending for the throne.
ENDTEXT
@ENDIF

@IF
TURN
turn=118
@THEN
TEXT
On 24th August, 1453, the Percies attack their main rivals in northern England, 
the Nevilles. Many powerful lords line up behind one faction or another, but their principal loyalties are either to the King or the Duke of York.
ENDTEXT
@ENDIF

@IF
TURN
turn=119
@THEN
TEXT
The English King, tired of the many defiances of some of the greatest magnates
in the land, quits London and journies to St Albans. There, he is attacked and 
captured by Richard, Duke of York. The Wars of the Roses begin, and English 
claims in France are taken no further. 
ENDTEXT
@ENDIF

@ENDEVENTS
