;   CIV II EVENTS - ANCIENT EMPIRES SERIES #2 (3500 BC)
;   "Seeds of Greatness - The Early Empires" Scenario, v1.1 (5/00)
;   (Greek Events)
;
;
@BEGINEVENTS

@IF
SCENARIOLOADED
@THEN
PLAYWAVEFILE
ae-3500b.wav
@ENDIF

@IF
SCENARIOLOADED
@THEN
DONTPLAYWONDERS
@ENDIF

@IF
citytaken
city=Hattusas
attacker=anybody
defender=Hittites
@THEN
justonce
text
O how ye mighty have fallen! Once invincible Hattusas
lies sacked and looted!
endtext
changemoney
receiver=TRIGGERATTACKER
amount=500
PLAYWAVEFILE
citysack.wav
@ENDIF

@IF
citytaken
city=Ur
attacker=anybody
defender=Babylonians
@THEN
justonce
text
Behold! "Ur of the Chaldees" has fallen to the enemy!
endtext
changemoney
receiver=TRIGGERATTACKER
amount=500
PLAYWAVEFILE
citysack.wav
@ENDIF

@IF
citytaken
city=Nineveh
attacker=anybody
defender=Assyrians
@THEN
justonce
text
The fires of Nineveh mount up to the skies. A terrible
retribution is visited upon her! 
endtext
changemoney
receiver=TRIGGERATTACKER
amount=500
PLAYWAVEFILE
citysack.wav
@ENDIF

@IF
citytaken
city=Memphis
attacker=anybody
defender=Egyptians
@THEN
justonce
text
Alas, mighty Memphis lies crushed beneath the invader's heel!
endtext
changemoney
receiver=TRIGGERATTACKER
amount=500
PLAYWAVEFILE
citysack.wav
@ENDIF

@IF
citytaken
city=Ecbatana
attacker=anybody
defender=Persians
@THEN
justonce
text
No longer protected by her mountainous redoubt, Ecbatana
feels the sting of the conqueror's lash!
endtext
changemoney
receiver=TRIGGERATTACKER
amount=500
PLAYWAVEFILE
citysack.wav
@ENDIF

@IF
citytaken
city=Mycenae
attacker=anybody
defender=Greeks
@THEN
justonce
text
Sacked and burned, "Golden Mycenae" meets with the fate of Troy!
endtext
changemoney
receiver=TRIGGERATTACKER
amount=500
PLAYWAVEFILE
citysack.wav
@ENDIF

@IF
citytaken
city=Knossos
attacker=anybody
defender=Minoans
@THEN
justonce
text
In the end, the seas prove to be a poor safeguard. Knossos burns!
endtext
changemoney
receiver=TRIGGERATTACKER
amount=500
PLAYWAVEFILE
citysack.wav
@ENDIF

@IF
TURN
turn=150
@THEN
TEXT
^The "Great Bull", Minos ascends to the throne of Crete.
^Truly, the Minoans now rule the seas!
ENDTEXT
CREATEUNIT
unit=Minos
owner=Minoans
veteran=yes
homecity=none
locations
23,47
24,46
25,47
endlocations
PLAYWAVEFILE
leader.wav
@ENDIF

@IF
TURN
turn=171
@THEN
TEXT
^The great "law-giver", Hammurabi ascends to the throne of Babylon.
^Behold the first of the "Great Kings"!
ENDTEXT
CREATEUNIT
unit=Hammurabi
owner=Babylonians
veteran=yes
homecity=none
locations
143,75
144,72
145,73
endlocations
PLAYWAVEFILE
leader.wav
@ENDIF

@IF
TURN
turn=190
@THEN
TEXT
^A mighty emperor, Mursilis I claims the throne of Hatti.
^Tremble all ye nations!
ENDTEXT
CREATEUNIT
unit=Mursilis I
owner=Hittites
veteran=yes
homecity=none
locations
75,15
74,14
76,18
endlocations
PLAYWAVEFILE
leader.wav
@ENDIF

@IF
TURN
turn=218
@THEN
TEXT
^The God-King, Ramesses II ascends to the throne of Egypt.
^His chariots shall shake the Earth!
ENDTEXT
CREATEUNIT
unit=Ramesses II
owner=Egyptians
veteran=yes
homecity=none
locations
57,89
56,88
58,90
endlocations
PLAYWAVEFILE
leader.wav
@ENDIF

@IF
TURN
turn=283
@THEN
TEXT
^A great king, Ashurbanipal ascends to the throne of Assyria.
^His armies shall descend upon ye like locusts!
ENDTEXT
CREATEUNIT
unit=Ashurbanipal
owner=Assyrians
veteran=yes
homecity=none
locations
112,34
113,33
114,32
endlocations
PLAYWAVEFILE
leader.wav
@ENDIF

@IF
TURN
turn=294
@THEN
TEXT
^A mighty warrior, Cyrus II lays claim to the throne of Persia.
^None may withstand his power and wisdom!
ENDTEXT
CREATEUNIT
unit=Cyrus II
owner=Persians
veteran=yes
homecity=none
locations
145,45
146,46
145,47
endlocations
PLAYWAVEFILE
leader.wav
@ENDIF

@IF
TURN
turn=315
@THEN
TEXT
^The great conqueror, Alexander ascends to the throne of Greece.
^The World lies prostrate before him!
ENDTEXT
CREATEUNIT
unit=Alexander
owner=Greeks
veteran=yes
homecity=none
locations
8,30
8,34
6,32
endlocations
PLAYWAVEFILE
leader.wav
@ENDIF

@IF
UNITKILLED
unit=Mursilis I
attacker=anybody
defender=Hittites
@THEN
TEXT
^Weep ye People of Hatti! Mursilis I has been slain in battle!
^The Hittite Army redeems his body for 500 Gold!
ENDTEXT
changemoney
receiver=TRIGGERATTACKER
amount=500
@ENDIF

@IF
UNITKILLED
unit=Hammurabi
attacker=anybody
defender=Babylonians
@THEN
TEXT
^Tremble O' Babylon! Hammurabi has been slain in battle!
^The victors scavenge 500 Gold from the field of battle!
ENDTEXT
changemoney
receiver=TRIGGERATTACKER
amount=500
@ENDIF

@IF
UNITKILLED
unit=Ashurbanipal
attacker=anybody
defender=Assyrians
@THEN
TEXT
^Woe unto Assyria! Ashurbanipal has been slain in battle!
^The victors ransom his battered corpse for 500 Gold!
ENDTEXT
changemoney
receiver=TRIGGERATTACKER
amount=500
@ENDIF

@IF
UNITKILLED
unit=Ramesses II
attacker=anybody
defender=Egyptians
@THEN
TEXT
^Ramesses II is slain in battle! Who will defend ye now, O Egypt?
^The victors loot 500 Gold from the Egyptian camp!
ENDTEXT
changemoney
receiver=TRIGGERATTACKER
amount=500
@ENDIF

@IF
UNITKILLED
unit=Cyrus II
attacker=anybody
defender=Persians
@THEN
TEXT
^A shudder sweeps across the Persian Empire! Cyrus II has been slain in battle!
^The exultant enemy loot 500 Gold from the battlefield!
ENDTEXT
changemoney
receiver=TRIGGERATTACKER
amount=500
@ENDIF

@IF
UNITKILLED
unit=Alexander
attacker=anybody
defender=Greeks
@THEN
TEXT
^A disaster of incomprehensible magnitude! Alexander has been slain in battle!
^The mournful Greek Army ransoms his body for 500 Gold!
ENDTEXT
changemoney
receiver=TRIGGERATTACKER
amount=500
@ENDIF

@IF
UNITKILLED
unit=Minos
attacker=anybody
defender=Minoans
@THEN
TEXT
^A terrible naval defeat claims the life of Minos of Crete!
^Enemy mariners find 500 Gold aboard his captured flagship!
ENDTEXT
changemoney
receiver=TRIGGERATTACKER
amount=500
@ENDIF

@IF
UNITKILLED
unit=Warriors
attacker=Greeks
defender=Barbarians
@THEN
TEXT
Another town is added to the Greek Empire! The defeated
survivors are enslaved and sent to till the fields of Mycenae.
The King takes 50 gold as his share of the booty!
ENDTEXT
changemoney
receiver=TRIGGERATTACKER
amount=50
CREATEUNIT
unit=Farmers
owner=Greeks
veteran=yes
homecity=none
locations
8,30
6,32
endlocations
@ENDIF

@IF
UNITKILLED
unit=Palace Guard
attacker=Greeks
defender=Barbarians
@THEN
TEXT
A powerful enemy city-state is conquered at last!
The sack adds 100 gold to Greek coffers,
and the victorious General is promoted to Royal Envoy!
ENDTEXT
changemoney
receiver=TRIGGERATTACKER
amount=100
CREATEUNIT
unit=Royal Envoy
owner=Greeks
veteran=yes
homecity=none
locations
8,30
6,32
endlocations
@ENDIF

@IF
UNITKILLED
unit=Caravan
attacker=Greeks
defender=anybody
@THEN
TEXT
A caravan is destroyed! The attackers pillage 80 gold from the wreckage.
ENDTEXT
changemoney
receiver=TRIGGERATTACKER
amount=80
@ENDIF

@IF
UNITKILLED
unit=Farmers
attacker=Greeks
defender=anybody
@THEN
TEXT
^Foreign peasants are captured by the Greeks. They are enslaved and
^shipped off to Mycenae!
ENDTEXT
CREATEUNIT
unit=Farmers
owner=Greeks
veteran=yes
homecity=none
locations
8,30
6,32
endlocations
@ENDIF

@IF
TURN
turn=75
@THEN
TEXT
Jason of Argos gathers his companions about him. "A traveler from the
distant shores of Ilios speaks of the fabulous Golden Fleece! Fellow
Argonauts, let us go forth and claim this fortune for the glory of Greece!"
ENDTEXT
CREATEUNIT
unit=Early Galley
owner=Greeks
veteran=true
homecity=none
locations
22,6
21,5
endlocations
@ENDIF
@IF
TURN
turn=75
@THEN
CREATEUNIT
unit=Bronze Infantry I
owner=Greeks
veteran=true
homecity=Argos
locations
20,6
23,5
endlocations
@ENDIF

@IF
TURN
turn=77
@THEN
TEXT
Across the Hellespont from Ilios (Troy), a band of adventurers stands
ready to join Jason on his quest!
ENDTEXT
CREATEUNIT
unit=Bronze Infantry I
owner=Greeks
veteran=true
homecity=none
locations
29,11
30,10
endlocations
@ENDIF

@IF
TURN
turn=78
@THEN
TEXT
An aged crone tells a cryptic tale. "Follow the watery passage north from Troy until
you reach the Black Sea and then sail toward the far eastern shore. Disembark at the
foot of the Golden Mountain and travel inland toward the cradle of the sun. You will
find the Fleece in a citadel deep within a valley, guarded by fierce protectors!"
ENDTEXT
CREATEUNIT
unit=farmers
owner=minoans
veteran=true
homecity=none
locations
35,39
34,38
endlocations
@ENDIF
@IF
TURN
turn=78
@THEN
CREATEUNIT
unit=Palace Guard
owner=minoans
veteran=true
homecity=none
locations
35,39
34,38
endlocations
@ENDIF

@IF
UNITKILLED
unit=Spearmen
attacker=Greeks
defender=Barbarians
@THEN
TEXT
Jason is victorious! The Argonauts have claimed the Golden Fleece and a vast
fortune of 500 gold! As they set sail for the land of their birth, a mighty legend
has been born!
ENDTEXT
changemoney
receiver=TRIGGERATTACKER
amount=500
CREATEUNIT
unit=farmers
owner=minoans
veteran=true
homecity=none
locations
34,50
33,49
endlocations
@ENDIF

@IF
TURN
turn=88
@THEN
TEXT
^Cycladic Pirates raid the Attic coast of Greece!
ENDTEXT
@THEN
createunit
owner=Barbarians
unit=Bronze Infantry I
veteran=true
homecity=none
locations
14,28
15,29
endlocations
@ENDIF
@IF
TURN
turn=88
@THEN
createunit
owner=Barbarians
unit=Bronze Infantry I
veteran=true
homecity=none
locations
14,28
15,29
endlocations
@ENDIF

@IF
TURN
turn=105
@THEN
createunit
owner=Minoans
unit=Bronze Infantry I
veteran=true
homecity=none
locations
3,37
3,35
endlocations
@ENDIF
@IF
TURN
turn=105
@THEN
createunit
owner=Greeks
unit=Farmers
veteran=false
homecity=none
locations
4,38
2,36
endlocations
@ENDIF

@IF
TURN
turn=106
@THEN
TEXT
The dreaded Minoan Sea Lords land on the Peloponnesus and issue their usual
demand for tribute and slaves. But this time, Theseus of Athens vows to resist.
"We will give you the sharp edge of our swords instead!", he cries.
ENDTEXT
makeaggression
who=Minoans
whom=Greeks
createunit
owner=Minoans
unit=Bronze Infantry II
veteran=true
homecity=none
locations
3,37
3,35
endlocations
@ENDIF

@IF
UNITKILLED
unit=Farmers
attacker=Minoans
defender=Greeks
@THEN
justonce
TEXT
^"If you will not give us slaves, then we will take them" cry the Minoans!
ENDTEXT
CREATEUNIT
unit=Farmers
owner=Minoans
veteran=yes
homecity=none
locations
21,15
18,32
endlocations
@ENDIF

@IF
TURN
turn=123
@THEN
TEXT
Paris, son of the King of Troy, has run off with Helen, wife to 
Menelaus of Sparta. Agamemnon is furious and vows to wreak a
great and bloody vengeance upon the Trojans!
ENDTEXT
CREATEUNIT
unit=farmers
owner=minoans
veteran=true
homecity=none
locations
21,35
28,20
endlocations
@ENDIF

@IF
TURN
turn=125
@THEN
TEXT
The sea churns and the earth trembles as a powerful Earthquake
shakes Mycenae! Some counsel that this is a warning from Poseidon,
the patron God of Troy. But in his rage, Agamemnon will not listen!
ENDTEXT
CREATEUNIT
unit=earthquake
owner=barbarians
veteran=false
homecity=none
locations
7,33
8,34
endlocations
@ENDIF

@IF
TURN
turn=127
@THEN
TEXT
The army of Greece is encamped before the walls of Troy!
ENDTEXT
CREATEUNIT
unit=Warriors
owner=Greeks
veteran=true
homecity=none
locations
29,15
endlocations
@ENDIF
@IF
TURN
turn=127
@THEN
createunit
owner=Barbarians
unit=Early Chariot
veteran=false
homecity=none
locations
30,14
endlocations
@ENDIF

@IF
UNITKILLED
unit=Warriors
attacker=Barbarians
defender=Greeks
@THEN
TEXT
The Greek Hero Achilles is slain by a javelin thrust to the heel!
ENDTEXT
CREATEUNIT
unit=Farmers
owner=minoans
veteran=yes
homecity=none
locations
22,28
26,38
endlocations
@ENDIF

@IF
TURN
turn=128
@THEN
TEXT
The Greek siege of Troy has lasted for ten long years, but now the
ruse of the Trojan Horse has gained them entry to the city.
Agamemnon orders the final assault!
ENDTEXT
CREATEUNIT
unit=Bronze Infantry I
owner=Greeks
veteran=true
homecity=none
locations
32,14
endlocations
@ENDIF
@IF
TURN
turn=128
@THEN
CREATEUNIT
unit=Ladder Tower
owner=Greeks
veteran=true
homecity=none
locations
32,14
endlocations
@ENDIF

@IF
UNITKILLED
unit=Early Chariot
attacker=Greeks
defender=Barbarians
@THEN
justonce
TEXT
Victory for Mycenae! Troy is sacked and burned with her people enslaved and her
treasure looted (300 gold). Paris and Priam are dead and Helen is reclaimed!
But Odysseus of Ithaca has angered the gods and a great storm blows his returning
ship far off course. His journey home will truly be an "Odyssey"!
ENDTEXT
changemoney
receiver=TRIGGERATTACKER
amount=300
PLAYWAVEFILE
citysack.wav
CREATEUNIT
unit=Pentekonter
owner=Greeks
veteran=true
homecity=none
locations
47,71
46,70
endlocations
@ENDIF

@IF
TURN
turn=199
@THEN
TEXT
^The quiet mountain near Akrotiri has awakened from the sleep of millenia.
^The rumbling and venting of steam disquiet many in the population. A small
^group gather their possessions and leave to colonize another island.
ENDTEXT
CREATEUNIT
unit=Farmers
owner=Minoans
veteran=yes
homecity=none
locations
25,11
26,38
endlocations
@ENDIF

@IF
TURN
turn=200
@THEN
TEXT
^The Theran volcano erupts, destroying the city of Akrotiri!
ENDTEXT
CHANGETERRAIN
terraintype=9
maprect
30,40,30,40,30,40,30,40
PLAYWAVEFILE
volcano.wav
@ENDIF
@IF
TURN
turn=200
@THEN
CHANGETERRAIN
terraintype=10
maprect
29,41,29,41,29,41,29,41
@ENDIF

@IF
TURN
turn=201
@THEN
TEXT
^Reports reach Mycenae of unparalleled destruction on Crete and the
^nearby islands of the Aegean! A rain of ash and pumice has devastated 
^forests and farmland alike! Fortunately for Greece, the prevailing
^winds send the cloud south and east!
ENDTEXT
CHANGETERRAIN
terraintype=7
maprect
24,48,24,48,24,48,24,48
@ENDIF
@IF
TURN
turn=201
@THEN
CHANGETERRAIN
terraintype=7
maprect
34,40,34,40,34,40,34,40
@ENDIF
@IF
TURN
turn=201
@THEN
CHANGETERRAIN
terraintype=7
maprect
33,47,33,47,33,47,33,47
@ENDIF

@IF
TURN
turn=220
@THEN
TEXT
^Several generations have passed since the volcano on
^Thera erupted. Those areas most affected by the ashfall
^have now become enormously fertile crop-growing regions!
^The devastated forests of the Aegean will take longer 
^to recover.
ENDTEXT
CHANGETERRAIN
terraintype=2
maprect
24,48,24,48,24,48,24,48
@ENDIF
@IF
TURN
turn=240
@THEN
CHANGETERRAIN
terraintype=3
maprect
34,40,34,40,34,40,34,40
@ENDIF
@IF
TURN
turn=240
@THEN
CHANGETERRAIN
terraintype=3
maprect
33,47,33,47,33,47,33,47
@ENDIF

@IF
TURN
turn=230
@THEN
TEXT
^Turmoil convulses the Ancient World! Seemingly from nowhere, the Sea Peoples
^descend in a massive invasion at many points along the Mediterranean coast!
ENDTEXT
createunit
owner=Barbarians
unit=Sea Peoples
veteran=true
homecity=none
locations
3,35
5,35
endlocations
@ENDIF
@IF
TURN
turn=230
@THEN
createunit
owner=Barbarians
unit=Sea Peoples
veteran=true
homecity=none
locations
3,35
5,35
endlocations
@ENDIF
@IF
TURN
turn=230
@THEN
createunit
owner=Barbarians
unit=Sea Peoples
veteran=true
homecity=none
locations
15,31
15,29
endlocations
@ENDIF
@IF
TURN
turn=230
@THEN
createunit
owner=Barbarians
unit=Sea Peoples
veteran=true
homecity=none
locations
32,22
33,19
endlocations
@ENDIF

@IF
TURN
turn=239
@THEN
TEXT
Dorian invaders emerge from the forests to the North!
Driven south by fiercer foes, they are determined to
establish new kingdoms in Greece!
ENDTEXT
createunit
owner=Barbarians
unit=Chariot III
veteran=true
homecity=none
locations
3,7
4,8
endlocations
@ENDIF
@IF
TURN
turn=239
@THEN
createunit
owner=Barbarians
unit=Chariot III
veteran=true
homecity=none
locations
3,7
4,8
endlocations
@ENDIF

@IF
TURN
turn=292
@THEN
TEXT
After generations of toil and degradation, the Helots of Sparta rise up in revolt!
ENDTEXT
createunit
owner=Barbarians
unit=Slave Revolt
veteran=true
homecity=none
locations
3,27
5,29
endlocations
@ENDIF
@IF
TURN
turn=292
@THEN
createunit
owner=Barbarians
unit=Ballista
veteran=true
homecity=none
locations
3,27
5,29
endlocations
@ENDIF

@IF
TURN
turn=299
@THEN
TEXT
The Great King of Persia grows weary of the meddlesome Greeks!
ENDTEXT
createunit
owner=Persians
unit=Desert Raiders
veteran=true
homecity=none
locations
17,23
16,22
endlocations
@ENDIF

@IF
TURN
turn=300
@THEN
TEXT
Darius of Persia makes good on his threats and lands an invasion
force near Marathon, on the shores of Euboea!
ENDTEXT
makeaggression
who=Persians
whom=Greeks
createunit
owner=Persians
unit=Phalanx II
veteran=true
homecity=none
locations
17,23
16,22
@ENDIF

@IF
TURN
turn=303
@THEN
TEXT
Silver has been discovered at Mt. Laurion!
The nearby city-state shall grow wealthy indeed!
ENDTEXT
CHANGETERRAIN
terraintype=9
maprect
15,33,15,33,15,33,15,33
PLAYWAVEFILE
leader.wav
@ENDIF

@IF
TURN
turn=313
@THEN
TEXT
A horde of Scythian tribesmen descends into Greece from the
Thracian highlands to the north! No city or village is spared
as they loot and pillage all that lies in their path!
ENDTEXT
createunit
owner=Barbarians
unit=Scythian Horde
veteran=true
homecity=none
locations
6,2
5,3
PLAYWAVEFILE
citysack.wav
@ENDIF
@IF
TURN
turn=313
@THEN
createunit
owner=Barbarians
unit=Scythian Horde
veteran=false
homecity=none
locations
6,2
5,3
endlocations
@ENDIF
@IF
TURN
turn=313
@THEN
createunit
owner=Barbarians
unit=Light Cavalry
veteran=true
homecity=none
locations
6,2
5,3
endlocations
@ENDIF

@IF
RANDOMTURN
denominator=150
@THEN
TEXT
^The skies darken and suddenly a huge storm sweeps in from the Mediterranean!
ENDTEXT
CREATEUNIT
unit=storm
owner=barbarians
veteran=false
homecity=none
locations
7,13
4,8
endlocations
PLAYWAVEFILE
storm.wav
@ENDIF

@ENDEVENTS