@BEGINEVENTS

@IF
SCENARIOLOADED
@THEN
DONTPLAYWONDERS
@ENDIF

@IF
TURN
turn=0
@THEN
TEXT
The year is 399 BC. The long and devastating Pelopponesian war has finally ended with a
decisive victory of Sparta and Persia over the Delian league. The Delian league has been
disbanded and Athens and Thebes where forced to become a member of the Spartan-controlled
Pelopponesian league. Sparta is now the leading power in Greece.
In the east, the Ionian cities are again struggling for independence in the massive shadow of the
Persian empire. The Spartans, proud of their Hegemony and believing to be invincible, supports
these cities, and this ended in a war with Persia. Athens and Thebes are still neutral, but their
sympathy to Persia cannot be ignored. It is just a matter of time until they get involved...
ENDTEXT
@ENDIF

@IF
CITYTAKEN
city=Sparta
attacker=Persians
defender=Spartans and Allies
@THEN
TEXT
Sparta was taken by the Persians! Athens and Thebes fear that Persia becomes the dominating
power of Greece and declare war on Persia!
ENDTEXT
PLAYWAVEFILE
BADNEWS.WAV
MAKEAGGRESSION
who=Thebans
whom=Persians
JUSTONCE
@ENDIF

@IF
CITYTAKEN
city=Sparta
attacker=Persians
defender=Spartans and Allies
@THEN
MAKEAGGRESSION
who=Delian League
whom=Persians
JUSTONCE
@ENDIF

@IF
NOSCHISM
defender=ANYBODY
@THEN
@ENDIF

@IF
NEGOTIATION
talker=ANYBODY
talkertype=HumanOrComputer
listener=Independent States
listenertype=HumanOrComputer
@THEN
@ENDIF

@IF
NEGOTIATION
talker=Independent States
talkertype=HumanOrComputer
listener=ANYBODY
listenertype=HumanOrComputer
@THEN
@ENDIF

@IF
NEGOTIATION
talker=ANYBODY
talkertype=HumanOrComputer
listener=Carthaginians
listenertype=HumanOrComputer
@THEN
@ENDIF

@IF
NEGOTIATION
talker=Carthaginians
talkertype=HumanOrComputer
listener=ANYBODY
listenertype=HumanOrComputer
@THEN
@ENDIF

@IF
NEGOTIATION
talker=ANYBODY
talkertype=HumanOrComputer
listener=Romans
listenertype=HumanOrComputer
@THEN
@ENDIF

@IF
NEGOTIATION
talker=Romans
talkertype=HumanOrComputer
listener=ANYBODY
listenertype=HumanOrComputer
@THEN
@ENDIF

@IF
CITYTAKEN
city=Athinai
attacker=ANYBODY
defender=Delian League
@THEN
TEXT
Athens taken! The city is burned to the ground and the whole treasury is
plundered!
ENDTEXT
CHANGEMONEY
receiver=TRIGGERATTACKER
amount=3000
PLAYWAVEFILE
BADNEWS.WAV
JUSTONCE
@ENDIF

@IF
UNITKILLED
unit=Immortals
attacker=anybody
defender=anybody
@THEN
TEXT
^The Immortal 10,000 are defeated in battle. The Persian army loses respect
in the enemy's lines, but, even worse, under it's own people.
ENDTEXT
CHANGEMONEY
receiver=TRIGGERATTACKER
amount=-200
PLAYWAVEFILE
BADNEWS.WAV
@ENDIF

@IF
CITYTAKEN
city=Thebai
attacker=ANYBODY
defender=Thebans
@THEN
TEXT
^Thebes falls! Greece loses it's head- and most powerful state!
ENDTEXT
CHANGEMONEY
receiver=TRIGGERATTACKER
amount=3000
PLAYWAVEFILE
BADNEWS.WAV
JUSTONCE
@ENDIF

@IF
CITYTAKEN
city=Sardeis
attacker=ANYBODY
defender=Persians
@THEN
TEXT
^Sardis falls! Once again, after the Greek massacre in 498BC,
people flee and take or destroy all their property. What makes it even worse
is the fact, that Persia loses it's largest and most important city in the
western empire. The Persians immediately build up a small invading force
that is supposed to free the city and safely bring back the refugees.
ENDTEXT
CREATEUNIT
unit=Pers. Archers
owner=Persians
veteran=no
homecity=none
locations
67,43
67,45
66,42
68,44
65,45
66,46
endlocations
JUSTONCE
@ENDIF

@IF
CITYTAKEN
city=Epidauros
attacker=ANYBODY
defender=ANYBODY
@THEN
TEXT
^Epidauros has fallen! Peasants flee into the mountains!
ENDTEXT
CREATEUNIT
unit=Peasants
owner=Spartans and Allies
veteran=no
homecity=none
locations
54,46
53,45
endlocations
JUSTONCE
@ENDIF

@IF
UNITKILLED
unit=Pyramids
attacker=Persians
defender=anybody
@THEN
TEXT
^The Persians win control over the Pyramids after a long heroic defense of
the Egyptians. Some Egyptians manage to flee and form a milita, others are
killed by the Persians. Although priests warn from that, the Persians raid
one of the towering tombs and plunder a large treasury, worth 500 talents.
ENDTEXT
CREATEUNIT
unit=Peasants
owner=Independent States
veteran=no
homecity=none
locations
67,67
69,79
70,82
69,85
endlocations
JUSTONCE
@ENDIF

@IF
UNITKILLED
unit=Pyramids
attacker=Persians
defender=anybody
@THEN
CHANGEMONEY
receiver=Persians
amount=500
JUSTONCE
@ENDIF

@IF
CITYTAKEN
city=Ephesos
attacker=Persians
defender=ANYBODY
@THEN
TEXT
^Ephesus is  sacked and largely burned by the Persians. Out of the ruins,
they can gather food and other reserves that they can sell on their markets
for 70 talents.
ENDTEXT
CHANGEMONEY
receiver=Persians
amount=70
JUSTONCE
@ENDIF

@IF
UNITKILLED
unit=Hoplite
attacker=Persians
defender=anybody
@THEN
TEXT
^A greek Hoplite unit is defeated in battle. Survivors offer their service to
the king.
ENDTEXT
CREATEUNIT
unit=Hoplite
owner=Persians
veteran=yes
homecity=none
locations
100,54
108,56
97,47
endlocations
@ENDIF

@IF
CITYTAKEN
city=Aradus
attacker=Persians
defender=ANYBODY
@THEN
TEXT
^The Persians sack and plunder Aradus! Is this the end of an independent
Phoenecia? Scared tradesmen offer the king 50 talents for tribute.
ENDTEXT
CHANGEMONEY
receiver=Persians
amount=50
JUSTONCE
@ENDIF

@IF
CITYTAKEN
city=Abydos
attacker=Persians
defender=ANYBODY
@THEN
TEXT
^Abydos was sacked by the Persians! Peasants and farmers flee to nearby
villages and cities! The Persians re-gain one of the most important Harbors
in Asia Minor. They plunder an amount of 70 talents.
ENDTEXT
CHANGEMONEY
receiver=Persians
amount=70
JUSTONCE
@ENDIF

@IF
CITYTAKEN
city=Abydos
attacker=Persians
defender=ANYBODY
@THEN
CREATEUNIT
unit=Peasants
owner=TRIGGERDEFENDER
veteran=no
homecity=none
locations
63,45
63,37
62,48
63,51
endlocations
@ENDIF

@IF
TURN
turn=24
@THEN
TEXT
^Persian-Spartan war escalates! Athens and Thebes declare war on Sparta!
ENDTEXT
@ENDIF

@IF
TURN
turn=24
@THEN
MAKEAGGRESSION
who=Delian League
whom=Spartans and Allies
@ENDIF

@IF
TURN
turn=24
@THEN
MAKEAGGRESSION
who=Thebans
whom=Spartans and Allies
@ENDIF

@IF
CITYTAKEN
city=Kyrene
attacker=Independent States
defender=ANYBODY
@THEN
TEXT
Kyrene taken by the Egyptians! Carthaginians declare war on Egypt in fear the again powerful
empire plans to overrun Carthage!
ENDTEXT
JUSTONCE
@ENDIF

@IF
CITYTAKEN
city=Kyrene
attacker=Independent States
defender=ANYBODY
@THEN
MAKEAGGRESSION
who=Carthaginians
whom=Independent States
JUSTONCE
@ENDIF

@IF
CITYTAKEN
city=Kyrene
attacker=Persians
defender=ANYBODY
@THEN
TEXT
Kyrene taken by the Persians! Carthaginians declare war on Persia in fear that the again powerful
empire might plan to overrun Carthage!
ENDTEXT
JUSTONCE
@ENDIF

@IF
CITYTAKEN
city=Kyrene
attacker=Persians
defender=ANYBODY
@THEN
MAKEAGGRESSION
who=Carthaginians
whom=Persians
JUSTONCE
@ENDIF

@IF
TURN
turn=0
@THEN
TEXT
^^ARTAXERXES
^^--The fall of the Spartan hegemony--
^^By Stefan Härtel
^^Playtesting:
^^Mr. Temba, Allard Höfelt
^^In charge of the graphics:
^^Allard Höfelt
^^Technical help:
^^Jesús Balsinde
ENDTEXT
PLAYWAVEFILE
BEGIN.WAV
@ENDIF

@IF
RANDOMTURN
denominator=6
@THEN
CREATEUNIT
unit=Medians
owner=Persians
veteran=yes
homecity=none
locations
97,47
endlocations
@ENDIF

@IF
RANDOMTURN
denominator=6
@THEN
CREATEUNIT
unit=Thracians
owner=Persians
veteran=yes
homecity=none
locations
66,40
66,44
endlocations
@ENDIF

@IF
RANDOMTURN
denominator=6
@THEN
CREATEUNIT
unit=Bactrians
owner=Persians
veteran=yes
homecity=Bactra
locations
142,34
endlocations
@ENDIF

@IF
RANDOMTURN
denominator=6
@THEN
CREATEUNIT
unit=Parthians
owner=Persians
veteran=yes
homecity=none
locations
97,47
endlocations
@ENDIF

@IF
RANDOMTURN
denominator=6
@THEN
CREATEUNIT
unit=Elamites
owner=Persians
veteran=yes
homecity=Susa
locations
100,54
endlocations
@ENDIF

@IF
UNITKILLED
unit=Camel
attacker=Persians
defender=ANYBODY
@THEN
TEXT
Persian troops catch a camel herd and domesticate it.
ENDTEXT
CREATEUNIT
unit=Camel riders
owner=Persians
veteran=no
homecity=none
locations
132,52
140,44
137,29
142,34
137,21
endlocations
@ENDIF

@IF
UNITKILLED
unit=Satrap
attacker=ANYBODY
defender=Persians
@THEN
TEXT
The satrap is dead, long live the satrap!
ENDTEXT
CHANGEMONEY
receiver=TRIGGERATTACKER
amount=300
@ENDIF

@IF
UNITKILLED
unit=Satrap
attacker=Persians
defender=ANYBODY
@THEN
TEXT
The Usurping satrap is captured! He is taken to the royal court in Susa where his destiny will be
decided.
ENDTEXT
PLAYCDTRACK
3
@ENDIF

@IF
CITYTAKEN
city=Sardeis
attacker=Persians
defender=ANYBODY
@THEN
TEXT
The usurping Sardis is retaken by the Persians. As punishment for the population, the city is burnt
to the ground and plundered. The Persians sell the stolen goods to Greeks and Carthaginians for
100 talents.
ENDTEXT
CHANGEMONEY
receiver=Persians
amount=100
JUSTONCE
@ENDIF

@IF
CITYTAKEN
city=Daskyleion
attacker=Persians
defender=ANYBODY
@THEN
TEXT
The revolting Daskyleion falls into the hands of the Persians! For punishment, they burn the city to
the ground and plunder the ruins, receiving an amount of 200 gold.
ENDTEXT
CHANGEMONEY
receiver=Persians
amount=200
JUSTONCE
@ENDIF

@IF
CITYTAKEN
city=Memphis
attacker=Persians
defender=Independent States
@THEN
TEXT
Memphis falls! Refugees flee to the nearby Pyramids and defend them at all costs!
ENDTEXT
CREATEUNIT
unit=Pyramids
owner=Independent States
veteran=no
homecity=none
locations
71,71
70,72
70,70
68,72
67,71
endlocations
JUSTONCE
@ENDIF

@IF
CITYTAKEN
city=Naukratis
attacker=Persians
defender=Independent States
@THEN
TEXT
Naukratis is taken by the Persians. In remembrance of the siege over the invading Athenians near
the town, they treat the inhabitants respectively.
ENDTEXT
JUSTONCE
@ENDIF

@IF
CITYTAKEN
city=Thebai
attacker=Persians
defender=Independent States
@THEN
TEXT
Thebes falls! Refugees flee as far south as Nubia and take all they have with them! The Persians
can collect a marginal sum of only 50 talents!
ENDTEXT
CHANGEMONEY
receiver=Persians
amount=50
JUSTONCE
@ENDIF

@IF
UNITKILLED
unit=Camp
attacker=ANYBODY
defender=ANYBODY
@THEN
TEXT
A nomad camp is overrun and plundered. The attacker receives 70 gold pieces.
ENDTEXT
CHANGEMONEY
receiver=TRIGGERATTACKER
amount=70
@ENDIF

@IF
CITYTAKEN
city=Persepolis
attacker=ANYBODY
defender=Persians
@THEN
TEXT
Persepolis falls! The city is plundered and eventually burned! The Persians lose their pride and
symbol of supreority! The attackers see it as the destruction of Persian opression!
ENDTEXT
PLAYWAVEFILE
BADNEWS.WAV
JUSTONCE
@ENDIF

@IF
CITYTAKEN
city=Persepolis
attacker=ANYBODY
defender=Persians
@THEN
JUSTONCE
CHANGETERRAIN
terraintype=1
maprect
108,56,109,57,108,58,107,57
@ENDIF

@IF
UNITKILLED
unit=Immortals
attacker=ANYBODY
defender=Persians
@THEN
CREATEUNIT
unit=Immortals
owner=Persians
veteran=yes
homecity=none
locations
108,56
0,0
0,0
0,0
0,0
0,0
0,0
0,0
0,0
endlocations
@ENDIF

@IF
TURN
turn=239
@THEN
TEXT
In the same year, Artaxerxes and Agesilaos die. In northern Greece, Philipp II takes over the
kingdom of Macedonia. The next couple of years will be peaceful to Greece, while Macedonia
fights in their own territory. But in only 3 years, Philipp will be king of a pretty large empire and proud
father of a son: Alexander. 21 years from now, ALL of Greece will be Macedonian; Sparta has
fallen, and Greece has fallen!
ENDTEXT
@ENDIF

@IF
TURN
turn=239
@THEN
TEXT
^^THE END
^^This is your last turn
ENDTEXT
PLAYWAVEFILE
END.WAV
@ENDIF

@IF
TURN
turn=1
@THEN
TEXT
Socrates is sentenced to death by Athenian court.
ENDTEXT
@ENDIF

@IF
TURN
turn=25
@THEN
TEXT
Thukydides, a well-known historian, who described the Pelopponesian war, dies.
ENDTEXT
@ENDIF

@IF
TURN
turn=55
@THEN
TEXT
Meh Tih, an important Chinese philosopher, dies.
ENDTEXT
@ENDIF

@IF
TURN
turn=73
@THEN
TEXT
Plato founds his Philosophic academy in Athens.
ENDTEXT
@ENDIF

@IF
TURN
turn=90
@THEN
TEXT
Aristoteles is born.
ENDTEXT
@ENDIF

@IF
TURN
turn=120
@THEN
TEXT
Plato teaches the 'Phaidon', which tells that the earth is round. Assumingly, it was discovered by
Archytas of Tarentum.
ENDTEXT
@ENDIF

@IF
TURN
turn=135
@THEN
TEXT
Hippokrates dies.
ENDTEXT
@ENDIF

@IF
RANDOMTURN
denominator=4
@THEN
TEXT
Scythian raids in northern Media reported!
ENDTEXT
CREATEUNIT
unit=Scythian Archers
owner=Independent States
veteran=yes
homecity=none
locations
97,39
96,40
98,40
100,40
99,41
97,41
98,38
99,39
99,34
endlocations
@ENDIF

@IF
UNITKILLED
unit=Elephant Herd
attacker=Carthaginians
defender=ANYBODY
@THEN
TEXT
The Carthaginians catch an elephant herd and domesticate it.
ENDTEXT
CREATEUNIT
unit=War Elephant
owner=Carthaginians
veteran=no
homecity=none
locations
33,43
30,42
0,0
0,0
0,0
0,0
0,0
0,0
0,0
endlocations
@ENDIF

@IF
CITYTAKEN
city=Susa
attacker=ANYBODY
defender=Persians
@THEN
TEXT
With pride, the invadors march through the gates of once so powerful Susa. The citizens 
sometimes attack single soldiers, but in all, resistence is small. Now, everyone knows: Persia will 
fall!
ENDTEXT
PLAYWAVEFILE
BADNEWS.WAV
JUSTONCE
@ENDIF

@IF
CITYTAKEN
city=Egbatána
attacker=ANYBODY
defender=Persians
@THEN
TEXT
Ecbatana, capital of Media and one of the 5 residences of the king is taken. The city is merciless 
plundered and more than half the population slaughtered, all others are sold for slavery. The 
attackers receive 500 talents.
ENDTEXT
CHANGEMONEY
receiver=TRIGGERATTACKER
amount=500
JUSTONCE
@ENDIF

@IF
CITYTAKEN
city=Tyrus
attacker=ANYBODY
defender=Persians
@THEN
TEXT
Tyrus falls into the hand of the enemy, and with it a great portion of the Phoenecian fleet!
ENDTEXT
CREATEUNIT
unit=War Galley
owner=TRIGGERATTACKER
veteran=yes
homecity=Tyrus
locations
79,55
0,0
0,0
0,0
0,0
0,0
0,0
0,0
0,0
endlocations
JUSTONCE
@ENDIF

@IF
CITYTAKEN
city=Tyrus
attacker=ANYBODY
defender=Persians
@THEN
CREATEUNIT
unit=War Galley
owner=TRIGGERATTACKER
veteran=yes
homecity=Tyrus
locations
79,55
0,0
0,0
0,0
0,0
0,0
0,0
0,0
0,0
endlocations
JUSTONCE
@ENDIF

@IF
CITYTAKEN
city=Babylon
attacker=ANYBODY
defender=Persians
@THEN
TEXT
Babylon falls!!!! Peasants flee to nearby cities! The Persians make all effort to regain this great 
city!
Meanwhile, the city is merciless plundered for an incredible amount of 2000 talents!
ENDTEXT
CREATEUNIT
unit=Immortals
owner=Persians
veteran=yes
homecity=Susa
locations
95,55
89,51
100,54
97,47
108,56
0,0
0,0
0,0
0,0
endlocations
CHANGEMONEY
receiver=TRIGGERATTACKER
amount=2000
JUSTONCE
@ENDIF

@IF
RANDOMTURN
denominator=25
@THEN
TEXT
In the east, a powerful Satrap appears to revolt against the Persian king.
ENDTEXT
CREATEUNIT
unit=Satrap
owner=Independent States
veteran=no
homecity=none
locations
122,36
121,35
121,33
119,33
118,32
119,31
122,34
120,36
119,37
endlocations
@ENDIF

@IF
TURN
turn=50
@THEN
TEXT
Major revolt in northern Media! An usurping satrap mobilizes a large force to march against 
Ecbatana!
ENDTEXT
CREATEUNIT
unit=Pers. Warrior
owner=Independent States
veteran=yes
homecity=none
locations
98,48
96,48
96,46
97,49
99,49
99,47
100,50
100,48
98,44
endlocations
@ENDIF

@IF
TURN
turn=50
@THEN
CREATEUNIT
unit=Pers. Warrior
owner=Independent States
veteran=no
homecity=none
locations
98,48
96,48
96,46
97,49
99,49
99,47
100,50
100,48
98,44
endlocations
@ENDIF

@IF
TURN
turn=50
@THEN
CREATEUNIT
unit=P Cavalry
owner=Independent States
veteran=no
homecity=none
locations
98,48
96,48
96,46
97,49
99,49
99,47
100,50
100,48
98,44
endlocations
@ENDIF

@IF
TURN
turn=50
@THEN
CREATEUNIT
unit=P Cavalry
owner=Independent States
veteran=no
homecity=none
locations
98,48
96,46
96,48
97,49
99,49
99,47
100,50
100,48
98,44
endlocations
@ENDIF

@IF
RANDOMTURN
denominator=4
@THEN
TEXT
Scythian raids in northern Media reported!
ENDTEXT
CREATEUNIT
unit=S. Horse Archers
owner=Independent States
veteran=yes
homecity=none
locations
97,39
96,40
98,40
100,40
99,41
97,41
98,38
99,39
99,34
endlocations
@ENDIF

@ENDEVENTS
