;   CIV II EVENTS - (1283 BC)
;   "The Odyssey" Scenario, v1.0 (10/00)
;
;
@DEBUG

@BEGINEVENTS

@IF
SCENARIOLOADED
@THEN
PLAYWAVEFILE
Odyssey.wav
@ENDIF

@IF
SCENARIOLOADED
@THEN
DONTPLAYWONDERS
@ENDIF

@IF
NEGOTIATION
talker=Anybody
talkertype=HumanOrComputer
listener=Anybody
listenertype=HumanOrComputer
@THEN

@ENDIF

@IF
citytaken
city=Troy
attacker=anybody
defender=anybody
@THEN
justonce
text
^The Ten Year Siege is over! The Greek Army sacks Troy and wreaks a bloody
^vengeance upon it's inhabitants. The fields around the city are strewn
^with the bones of the dead.
^
^Soon after, quarrels break out among the victors and the resulting discord
^causes each contingent to depart separately.
^
^Thus Odysseus and his men head for home, but along the way they decide to
^add to their spoils by attacking the city of Ismarus. They make camp near
^the city, and the Sailors lead a surprise assault!
endtext
CREATEUNIT
unit=Messenger
owner=Ismarans
veteran=yes
homecity=Ismarus
locations
106,80
endlocations
PLAYWAVEFILE
citysack.wav
@ENDIF

@IF
UNITKILLED
unit=Trojan Horse
attacker=Ismarans
defender=Ithacans
@THEN
justonce
text
^A Messenger arrives from Troy! He tells the tale of Odysseus and the
^fabulous Wooden Horse, to the amazement and consternation of all.
^But for Queen Penelope, it means only one thing - her beloved Husband
^Odysseus will soon be coming home!
endtext
@ENDIF

@IF
UNITKILLED
unit=Ciccone Warrior
attacker=Ithacans
defender=Ismarans
@THEN
justonce
text
Ithacan sailors slay the City Guards!
endtext
CREATEUNIT
unit=Rough Seas
owner=Oceans
veteran=no
homecity=None
locations
156,62
endlocations
@ENDIF

@IF
citytaken
city=Ismarus
attacker=Ithacans
defender=Ismarans
@THEN
justonce
text
^The Men of Ithaca sack the capital of the Ciccones! They take a rich haul
^of Gold and Wine. But the Ciccones are not so easily beaten. They rise up
^in revolt, leaving Odysseus no choice but to abandon the city and flee!
endtext
changemoney
receiver=TRIGGERATTACKER
amount=100
PLAYWAVEFILE
citysack.wav
CREATEUNIT
unit=Wine of Ismarus
owner=Ithacans
veteran=yes
homecity=None
locations
156,56
endlocations
@ENDIF

@IF
citytaken
city=Ismarus
attacker=Ismarans
defender=Ithacans
@THEN
justonce
text
^As Odysseus heads out to sea, a great storm begins to howl.
^The winds blow them inexorably to the southwest!
endtext
PLAYWAVEFILE
extra5.wav
CHANGETERRAIN
terraintype=10
maprect
151,57,151,57,151,57,151,57
GIVETECHNOLOGY
receiver=Ismarans
technology=0
@ENDIF

@IF
UNITKILLED
unit=Vision 1
attacker=Ithacans
defender=Oceans
@THEN
text
^As they reach Cape Malea, Odysseus has a vision from Zeus. "Your sacrifices
^to the Gods have been pitifully inadequate! A bright spark of anger has been
^lit in my breast, and I am not through with you yet," he booms! The howling
^Southeast wind does not relent, and the storm blows them out into the deeps!
endtext
CREATEUNIT
unit=Storm Clouds
owner=Olympians
veteran=no
homecity=None
locations
129,99
endlocations
PLAYWAVEFILE
odyssey1.wav
@ENDIF

@IF
TURN
turn=17
@THEN
TEXT
^As word spreads that Odysseus has been lost at sea, the young men of Ithaca
^gather at the palace. "Marry one of us," they cry! "First let me finish this
^Tapestry that I weave in memory of my dear husband," begs Penelope. "Only
^after it's done will I be ready to wed again!"
ENDTEXT
@ENDIF

@IF
UNITKILLED
unit=Lotus
attacker=Ithacans
defender=Ismarans
@THEN
text
^After nine days, the storm abates and the Ithacans find themselves in the
^Land of the Lotus Eaters. Some of the men eat the flower and overcome by
^lassitude, refuse to leave the island!
endtext
CREATEUNIT
unit=Storm Clouds
owner=Olympians
veteran=no
homecity=None
locations
47,115
endlocations
@ENDIF

@IF
UNITKILLED
unit=Lotus
attacker=Ithacans
defender=Oceans
@THEN
text
^Despite their protests, Odysseus gathers up his men and departs the
^island. They sail north into a thick, eerie fog.....
endtext
CREATEUNIT
unit=Polites
owner=Ithacans
veteran=yes
homecity=None
locations
42,112
endlocations
@ENDIF

@IF
UNITKILLED
unit=Goat
attacker=Ithacans
defender=Ismarans
@THEN
justonce
text
^Through the mist the Ithacans spot an island teeming with wildlife.
^They set up camp, and begin to feast on roast goat! From the heights,
^Odysseus spies more goats and a large cave on another island.
^Together with two Sailors and the heady Wine of Ismarus,
^he departs to investigate this natural wonder.
^
^But first they wait for the fog to clear...
endtext
CREATEUNIT
unit=Goat
owner=Ithacans
veteran=no
homecity=None
locations
53,85
endlocations
givetechnology
technology=99
receiver=Olympians
@ENDIF

@IF
UNITKILLED
unit=Goat
attacker=Ithacans
defender=Ismarans
@THEN
justonce
CREATEUNIT
unit=Thick Fog
owner=Olympians
veteran=no
homecity=None
locations
45,89
endlocations
@ENDIF

@IF
receivedtechnology
receiver=Olympians
technology=99
@THEN
justonce
CHANGETERRAIN
terraintype=10
maprect
48,86,48,86,48,86,48,86
@ENDIF

@IF
UNITKILLED
unit=Goat
attacker=Ithacans
defender=Oceans
@THEN
justonce
text
^As Odysseus captures some goats, the mists close in behind the ship
^and all the Sailors take the Wine ashore. One Ithacan sprints ahead,
^seeking to be the first to investigate the cave.
endtext
CREATEUNIT
unit=Thick Fog
owner=Oceans
veteran=no
homecity=None
locations
48,86
endlocations
PLAYWAVEFILE
odyssey4.wav
@ENDIF

@IF
UNITKILLED
unit=Sailors
attacker=Oceans
defender=Ithacans
@THEN
just once
text
^Odysseus and his men enter the cave, and find it to be the home of a giant!
^Suddenly the entrance is blocked by the mighty Cyclops Polyphemus, son of the ocean
^god Poseidon. With scarcely a word he grabs one of the sailors and devours him whole!
^
^Trapped in the cave, Odysseus devises a desperate plan. He offers up the
^Wine of Ismarus and the Cyclops heedlessly drains the jug. His speech slurring,
^the drunken giant reels and then crashes to the ground!
endtext
CREATEUNIT
unit=Rocks
owner=Oceans
veteran=no
homecity=None
locations
45,85
endlocations
givetechnology
technology=98
receiver=Olympians
@ENDIF

@IF
UNITKILLED
unit=Cyclops
attacker=Ithacans
defender=Oceans
@THEN
text
^As the Cyclops lies unconscious upon the floor, Odysseus and his men toast
^a tree branch in the fire, and then plunge it into the single sleeping eye!
^Roaring in pain, the Blinded Cyclops springs to his feet and guards the exit.
^
^"How are we now to escape from the cave?", Odysseus wonders.
endtext
CREATEUNIT
unit=Blind Cyclops
owner=Oceans
veteran=Yes
homecity=None
locations
51,87
endlocations
@ENDIF

@IF
receivedtechnology
receiver=Olympians
technology=98
@THEN
justonce
CHANGETERRAIN
terraintype=10
maprect
46,82,46,82,46,82,46,82
@ENDIF

@IF
receivedtechnology
receiver=Olympians
technology=98
@THEN
justonce
CHANGETERRAIN
terraintype=10
maprect
48,86,48,86,48,86,48,86
@ENDIF

@IF
UNITKILLED
unit=Cave
attacker=Ithacans
defender=Oceans
@THEN
text
^Odysseus tricks the blind Cyclops by hiding amongst the
^sheep and sneaking out of the cave!
endtext
CREATEUNIT
unit=Sailors
owner=Ithacans
veteran=yes
homecity=None
locations
47,83
endlocations
@ENDIF

@IF
UNITKILLED
unit=Wine of Ismarus
attacker=Oceans
defender=Ithacans
@THEN
text
Do not waste time, Odysseus! Gather your men and flee!
endtext
@ENDIF

@IF
UNITKILLED
unit=Rocks
attacker=Ithacans
defender=Oceans
@THEN
justonce
text
^As they sail off, Odysseus taunts Polyphemus, who in turn hurls giant
^rocks toward the sound of the Ithacans' voice. It's a narrow escape!
^The shaken crew sails around the island and heads into the Northeast mist. 
endtext
@ENDIF

@IF
UNITKILLED
unit=Goat
attacker=Oceans
defender=Ithacans
@THEN
text
^Raging in his pain and frustration, Polyphemus the Cyclops begs
^his father to take revenge upon Odysseus. Poseidon is furious,
^but decides to bide his time.
endtext
CREATEUNIT
unit=Thick Fog
owner=Olympians
veteran=no
homecity=None
locations
48,86
endlocations
@ENDIF

@IF
UNITKILLED
unit=Vision 2
attacker=Ithacans
defender=Oceans
@THEN
text
^The tired crew reaches the Palace of Aeolus, Guardian of the Winds,
^where they seek rest, sustenance, and advice. "First return from whence
^you have come" suggests Aeolus, "and then South of Cyclops Land you'll
^find fair weather, smooth sailing, and a constant Northeast wind".
^
^As the Ithacans depart, he secretly gives Odysseus a Bag containing
^all the other winds. "Don't release them until your feet are planted
^on the soil of Ithaca", Aeolus warns!
endtext
CREATEUNIT
unit=Bag of Winds
owner=Ithacans
veteran=yes
homecity=None
locations
56,74
endlocations
givetechnology
technology=97
receiver=Olympians
PLAYWAVEFILE
odyssey1.wav
@ENDIF

@IF
UNITKILLED
unit=Vision 2
attacker=Ithacans
defender=Oceans
@THEN
CREATEUNIT
unit=Thick Fog
owner=Olympians
veteran=no
homecity=None
locations
48,86
endlocations
@ENDIF

@IF
receivedtechnology
receiver=Olympians
technology=97
@THEN
justonce
CHANGETERRAIN
terraintype=10
maprect
47,89,47,89,47,89,47,89
@ENDIF

@IF
UNITKILLED
unit=Vision 3
attacker=Ithacans
defender=Oceans
@THEN
text
^After weeks of steady sailing, at last the island of Ithaca is in sight.
^Exhausted from manning the tiller, Odysseus closes his eyes and begins to snore.
^But now the crew murmurs greedily amongst themselves, "Why should Odysseus get
^to keep that bulging bag to himself? It's certainly full of gold!"
^
^Let's share it out whilst he sleeps!"
endtext
@ENDIF

@IF
UNITKILLED
unit=Greed
attacker=Ithacans
defender=Oceans
@THEN
text
^As the sailors open the Bag of Winds, a howling tempest erupts!
^The violent storm drives them all the way back to the Isle of Aeolus,
^with Odysseus berating the crew at every turn.
endtext
CREATEUNIT
unit=Vision 4
owner=Oceans
veteran=no
homecity=None
locations
55,73
endlocations
givetechnology
technology=92
receiver=Olympians
@ENDIF

@IF
receivedtechnology
receiver=Olympians
technology=92
@THEN
justonce
CHANGETERRAIN
terraintype=10
maprect
56,74,56,74,56,74,56,74
@ENDIF

@IF
UNITKILLED
unit=Vision 4
attacker=Ithacans
defender=Oceans
@THEN
text
^When the bedraggled Ithacans arrive once more upon his doorstep,
^King Aeolus is at first surprised and then outraged when he hears
^their story. Refusing all entreaties, he casts them out! 
endtext
CREATEUNIT
unit=Thick Fog
owner=Olympians
veteran=no
homecity=None
locations
54,78
endlocations
@ENDIF

@IF
UNITKILLED
unit=Vision 5
attacker=Ithacans
defender=Oceans
@THEN
text
^After several days sail amidst a thick and depressing fog, the Ithacans
^spot the entrance to a harbor. Desperate for water and food, the Fleet
^sails in through the narrow entrance. But feeling uneasy, Odysseus anchors
^his own vessel just beyond the mouth of the inlet.
endtext
CREATEUNIT
unit=Ship of Odysseus
owner=Ithacans
veteran=yes
homecity=None
locations
28,44
endlocations
@ENDIF

@IF
UNITKILLED
unit=Vision 6
attacker=Ithacans
defender=Oceans
@THEN
text
Several Sailors gather wood on the opposite shore.
endtext
CREATEUNIT
unit=Sailor Marine
owner=Ithacans
veteran=yes
homecity=None
locations
27,43
endlocations
@ENDIF

@IF
UNITKILLED
unit=Vision 7
attacker=Ithacans
defender=Oceans
@THEN
text
^At the foot of the harbor lies a small, deserted town. Realizing they
^are completely lost, Odysseus sends a group of Sailors into town in
^search of people and information. Meanwhile, all the wood-gatherering
^Sailor Marines are picked up by Odysseus' ship.
endtext
CREATEUNIT
unit=Thick Fog
owner=Olympians
veteran=no
homecity=None
locations
33,51
endlocations
PLAYWAVEFILE
odyssey5.wav
@ENDIF

@IF
citytaken
city=Laestrygonia
attacker=Ithacans
defender=Laestrygonians
@THEN
justonce
text
^Several of the Ithacans come running back into town with dreadful news.
^This is the Land of the Laestrygonians, a tribe of man-eating cannibals!
^Worst of all, they have blocked the entrance to the harbor, trapping the
^Fleet inside! Odysseus, Eurylochus, Polites, and several Sailors scramble
^desperately ashore, hoping to reach the ship just outside the bay!
endtext
CREATEUNIT
unit=Laestrygon
owner=Laestrygonians
veteran=yes
homecity=None
locations
31,43
endlocations
@ENDIF

@IF
citytaken
city=Laestrygonia
attacker=Ithacans
defender=Laestrygonians
@THEN
justonce
CREATEUNIT
unit=Boulders
owner=Laestrygonians
veteran=no
homecity=None
locations
29,47
endlocations
@ENDIF

@IF
citytaken
city=Laestrygonia
attacker=Laestrygonians
defender=Ithacans
@THEN
justonce
text
^As the Laestrygonians chase the Sailors out of town, another group
^appears on the cliffs surrounding the harbor. Clearly they plan to
^use large Boulders to smash the ships trapped inside. The plight of
^the Ithacans is desperate! Odysseus saves those he can and
^sorrowfully sails East, leaving the rest to their fate!
endtext
CREATEUNIT
unit=Rock Throwers
owner=Laestrygonians
veteran=yes
homecity=None
locations
31,45
32,46
31,47
endlocations
@ENDIF

@IF
UNITKILLED
unit=Fleet of Ithaca
attacker=Laestrygonians
defender=Ithacans
@THEN
text
^As Odysseus and the lucky survivors sail away, the screams of dying men
^echo in their heads. The omnipresent fog worsens the already somber mood.
^But at last the mists begin to thin and fade until finally there in the
^distance lies a beautiful sun-drenched land!
endtext
@ENDIF

@IF
UNITKILLED
unit=Vision 8
attacker=Ithacans
defender=Oceans
@THEN
text
^The ship lies anchored in a beautiful bay, at the mouth of a small river.
^No one is eager to do any exploring, but Odysseus insists until finally
^Eurylochus volunteers to head up the river in search of Food. All the other
^men wait aboard ship while Odysseus climbs a nearby mountain alone.
endtext
CREATEUNIT
unit=Thick Fog
owner=Olympians
veteran=no
homecity=None
locations
39,43
endlocations
PLAYWAVEFILE
italy.wav
@ENDIF

@IF
UNITKILLED
unit=Eurylochus
attacker=Oceans
defender=Ithacans
@THEN
just once
text
^Eurylochus finds a bountiful table, laden with good Food and Fine Wine.
^Overcome by hunger, he and his men immediately start to eat. But after
^only a few bites they begin to feel very strange. The meal was bewitched!
^Within moments, all who ate the food have been turned into swine!
endtext
CREATEUNIT
unit=Swine
owner=Oceans
veteran=no
homecity=Circe's Palace
locations
47,39
endlocations
@ENDIF

@IF
UNITKILLED
unit=Hermes
attacker=Ithacans
defender=Oceans
@THEN
text
^At the top of the mountain, Odysseus is surprised to meet Hermes, the
^Messenger of the Gods. "Do not be too enthralled by this land" he warns,
^"for it is the home of the Witch Circe! Take this potion, for you will
^need it when you encounter the enchantress in her lair. But you may not
^carry it yourself, and must entrust it to the oldest and weakest member
^of your crew. Then together you must confront the witch at the very
^gates of her Palace!" 
endtext
CREATEUNIT
unit=Potion of Hermes
owner=Ithacans
veteran=yes
homecity=None
locations
44,44
endlocations
@ENDIF

@IF
UNITKILLED
unit=Circe
attacker=Ithacans
defender=Oceans
@THEN
text
^Protected by the potion, Circe's magic has no effect upon Odysseus! "Your
^powers are greater than mine!", she cries. "At last a man worthy of my favors.
^Come, come to my bed." "Only after you change the bewitched Swine back to Men,
^else what kind of leader would I be?" replies Odysseus. "Enter my Palace and
^it shall be done," proclaims the enchantress!
endtext
CREATEUNIT
unit=Circe
owner=Olympians
veteran=yes
homecity=None
locations
45,39
44,40
43,39
endlocations
@ENDIF

@IF
citytaken
city=Circe's Palace
attacker=Ithacans
defender=Oceans
@THEN
justonce
text
^After several months of frolic and ease, Odysseus finally insists that it's
^time to go. "We must return to Ithaca, but we are lost and have no idea how
^to make our return!" "The way will be long and hard, but I only know a part
^of it", says Circe. "For the rest, you must journey to the Gates of Hades,
^there to consult the prophet Tiresias!" "And how may a mortal man do such a
^thing and return?" questions Odysseus. "By entering into a deathlike trance
^and traveling forth over the Western Sea as a shade!"
^
^"Come now, are you ready?" asks the sorceress. "Yesssss...."
endtext
PLAYWAVEFILE
circe.wav
CREATEUNIT
unit=Shade of Odysseus
owner=Ithacans
veteran=yes
homecity=None
locations
40,34
endlocations
@ENDIF

@IF
citytaken
city=Circe's Palace
attacker=Ithacans
defender=Oceans
@THEN
justonce
CREATEUNIT
unit=Eurylochus
owner=Ithacans
veteran=yes
homecity=None
locations
48,38
endlocations
@ENDIF

@IF
UNITKILLED
unit=Gates of Hades
attacker=Ithacans
defender=Oceans
@THEN
text
^After turning away the shades of many former friends, at last the
^prophet Tiresias appears before Odysseus. "Mark my words well" he
^proclaims "for a great trial lies before you. Circe can speak of
^the fearsome monsters which yet await, but the greatest test will
^come when you return home. Your family is beset by men who would
^marry your wife! Like a nest of vipers, they plot against you! But
^before that you will face a terrible choice: Starvation or Angering
^the Gods beyond even their current fury!
^
^And then, like a man waking from a dream, Odysseus returns to the
^world of sound and light!
endtext
CREATEUNIT
unit=Suitors
owner=Barbarians
veteran=yes
homecity=None
locations
109,79
endlocations
givetechnology
technology=96
receiver=Olympians
@ENDIF

@IF
receivedtechnology
receiver=Olympians
technology=96
@THEN
justonce
CHANGETERRAIN
terraintype=10
maprect
42,44,42,44,42,44,42,44
@ENDIF

@IF
receivedtechnology
receiver=Olympians
technology=96
@THEN
justonce
text
^As Odysseus and his men prepare to leave, Circe tells him what she
^knows of the road ahead. "There are Sirens whose Song is Death for
^Mariners. And then The Clashing Rocks which will crush your ship if
^you aren't nimble and quick. The Monsters Scylla and Charybdis will
^present you a fatal choice. And then the path home lies before you!
^
^Go forth, noble Odysseus, and know that my love journeys with you!"
endtext
CHANGETERRAIN
terraintype=10
maprect
41,39,41,39,41,39,41,39
@ENDIF

@IF
UNITKILLED
unit=Vision 9
attacker=Ithacans
defender=Oceans
@THEN
text
^The weather is perfect and the countryside so breathtaking that
^only a deep homesickness keeps the crew at sea. Perhaps the Gods
^are smiling upon them at last!
^
^ SAVE THE GAME AS ODY1.SAV
^ RUN ODYSSEY.BAT FILE
^ SELECT CHAPTER 2
endtext
PLAYWAVEFILE
italy.wav
@ENDIF

@ENDEVENTS