@BEGINEVENTS

@IF
NOSCHISM
defender=ANYBODY
@THEN
@ENDIF

@IF
NEGOTIATION
talker=Utd Fed of Planets
talkertype=HumanOrComputer
listener=ANYBODY
listenertype=HumanOrComputer
@THEN
@ENDIF

@IF
NEGOTIATION
talker=Dominion
talkertype=HumanOrComputer
listener=ANYBODY
listenertype=HumanOrComputer
@THEN
@ENDIF

@IF
NEGOTIATION
talker=Cardassian Union
talkertype=HumanOrComputer
listener=Utd Fed of Planets
listenertype=HumanOrComputer
@THEN
@ENDIF

@IF
NEGOTIATION
talker=ANYBODY
talkertype=HumanOrComputer
listener=Utd Fed of Planets
listenertype=HumanOrComputer
@THEN
@ENDIF

@IF
NEGOTIATION
talker=ANYBODY
talkertype=HumanOrComputer
listener=Dominion
listenertype=HumanOrComputer
@THEN
@ENDIF

@IF
NEGOTIATION
talker=ANYBODY
talkertype=HumanOrComputer
listener=Breen Confederation
listenertype=HumanOrComputer
@THEN
@ENDIF

@IF
TURN
turn=-1
@THEN
MAKEAGGRESSION
who=Breen Confederation
whom=Utd Fed of Planets
@ENDIF

@IF
TURN
turn=-1
@THEN
MAKEAGGRESSION
who=Imperial Klingon Empire
whom=Cardassian Union
@ENDIF

@IF
TURNINTERVAL
interval=-1
@THEN
MAKEAGGRESSION
who=Romulan Star Empire
whom=Dominion
@ENDIF

@IF
SCENARIOLOADED
@THEN
PLAYWAVEFILE
INTRO.WAV
@ENDIF

@IF
TURN
turn=1
@THEN
PLAYWAVEFILE
INTRO.WAV
CHANGETERRAIN
terraintype=6
maprect
48,4,48,4,48,4,48,4
@ENDIF

@IF
TURN
turn=1
@THEN
TEXT
^
^Act I, Scene I - APPOCOLYPSE RISING
^
^^ Starfleet Intelligence reports a combined Dominion-Cardassian Armada on its way
^^ to secure the wormhole and access from the Gamma Quadrant. Chief O'brien has
^^ mined the entrance to the wormhole with self-replicating mines while elements
^^ of the Seventh Fleet have begun to arrive at Bajor.
^
^^ As Commander of Federation Forces, you can either abandon Bajor and DS9 in favour
^^ of regrouping your forces near Vulcan or you may attempt to defend the Kalandra-
^^ Bajor-Betazed axis against superior forces.
^
ENDTEXT
PLAYWAVEFILE
ZMINE.WAV
@ENDIF

@IF
UNITKILLED
unit=Klingon Inf
attacker=ANYBODY
defender=Imperial Klingon Empire
@THEN
TEXT
^
^Act I, Scene II - THE RECKONING
^
^^ Mad with hatred because of the death of his daughter, Gul Dukat manages to summon
^^ a pah-wraith, a banished evil faction of the Bajorian Prophets (Wormhole Aliens)
^^ and in the process kills Jadzia Dax on DS9. Her symbiont is saved and transferred
^^ to a fellow Trill, Ezri. The pah-wraiths stage a revolt within the Celestial Temple
^^ (wormhole) and the fate of the Alpha Quadrant now hangs on their success or failure.
^
ENDTEXT
PLAYWAVEFILE
INTRO.WAV
JUSTONCE
@ENDIF

@IF
CITYTAKEN
city=Bajor
attacker=ANYBODY
defender=Utd Fed of Planets
@THEN
TEXT
^
^^ Bajor has fallen. The Bajorans have no choice but to abandon their affiliation to
^^ the Federation and the horror of the Cardassian Occupation from years ago returns.
^
^^ Sisko receives a vision which tells him to search for the ORB of the EMMISARY.
^^ It is located on a unpopulated dessert planet under the sand.
^
ENDTEXT
JUSTONCE
CHANGETERRAIN
terraintype=9
maprect
38,56,38,56,38,56,38,56
@ENDIF

@IF
UNITKILLED
unit=DS9
attacker=ANYBODY
defender=Utd Fed of Planets
@THEN
TEXT
^
^Act I, Scene III - SOLDIERS OF THE EMPIRE
^
^^ Deep Space Nine falls under the control of the Dominion Alliance and the HQ of
^^ the Seventh Fleet is transferred to Starbase 375. Kira and Odo stay behind as
^^ part of the Bajorian civilian administration and secretly await the return of
^^ Starfleet as liberators (Sisko leaves his baseball).
^
ENDTEXT
PLAYWAVEFILE
INTRO.WAV
JUSTONCE
@ENDIF

@IF
UNITKILLED
unit=Self Rep Mines
attacker=ANYBODY
defender=Utd Fed of Planets
@THEN
TEXT
^
^^ Jem'Hadar forces begin to sacrifice themselves in an effort to clear the mouth
^^ of the wormhole. It may be a good idea to develop the Early Warning Grid in
^^ preparations for full scale hostilities.
^
ENDTEXT
JUSTONCE
@ENDIF

@IF
UNITKILLED
unit=Photon Cannon
attacker=ANYBODY
defender=Utd Fed of Planets
@THEN
TEXT
^
^Act I, Scene IV - WHAT YOU LEAVE BEHIND
^
^^ Starbase 375, HQ of the 7th Fleet is overrun by the Dominion Alliance. Sloane of
^^ Section 31 is captured during the unorganized evacuation and after some 'exotic'
^^ interrogation techniques, he surrenders a cure to the Founder's disease.
^
^^ The DOMINION founders can resume their clandestine activities now that they
^^ have been cured. You are advised to expand your fleet of Oberths.
^
ENDTEXT
PLAYWAVEFILE
INTRO.WAV
JUSTONCE
GIVETECHNOLOGY
receiver=Dominion
technology=50
@ENDIF

@IF
TURN
turn=24
@THEN
TEXT
^
^Act I, Scene V - A TIME TO STAND
^
^^ U.S.S. Valiant, pressumed loss on a training mission when it was trapped behind
^^ enemy lines reports in. Captained by Cadet Tim Watters of Red Squad, the Defiant 
^^ class ship reports sighting a DOMINION Battleship. He reports that it is extremely 
^^ well armed and heavily shielded, rendering it practically impervious to even the
^^ Valiant's weapons. They were only able to escape because of their cloaking device.
^
^^ Cadet Nog who was also on the Valiant reports seeing a dessert planet or two.
^
ENDTEXT
CREATEUNIT
unit=Defiant
owner=Utd Fed of Planets
veteran=yes
homecity=None
locations
53,13
52,14
54,14
56,14
endlocations
PLAYWAVEFILE
INTRO.WAV
@ENDIF

@IF
TURN
turn=24
@THEN
CREATEUNIT
unit=Emissary's Orb
owner=Dominion
veteran=no
homecity=None
locations
48,4
48,14
endlocations
@ENDIF

@IF
TURN
turn=25
@THEN
CREATEUNIT
unit=War Cruiser
owner=Dominion
veteran=yes
homecity=None
locations
45,9
endlocations
@ENDIF

@IF
TURN
turn=59
@THEN
GIVETECHNOLOGY
receiver=Dominion
technology=33
@ENDIF

@IF
CITYTAKEN
city=Earth
attacker=ANYBODY
defender=Utd Fed of Planets
@THEN
TEXT
^
^Act I, Scene VI - PARADISE LOST
^
^^ After a long siege, the Dominion troops finally conquer Earth and the United
^^ Federation of Planets ceases to exist. One by one, all of the Alpha Quadrant's
^^ civilisations come under Dominion control.
^
^^ Perhaps one day the Alpha Quadrant will be able to shake the yoke of oppression,
^^ but that will be after centuries of suffering..all because of YOU.
^
ENDTEXT
PLAYWAVEFILE
INTRO.WAV
JUSTONCE
DESTROYACIVILIZATION
whom=Utd Fed of Planets
@ENDIF

@IF
UNITKILLED
unit=Emissary's Orb
attacker=ANYBODY
defender=ANYBODY
@THEN
PLAYWAVEFILE
INTRO.WAV
JUSTONCE
@ENDIF

@IF
UNITKILLED
unit=Emissary's Orb
attacker=ANYBODY
defender=ANYBODY
@THEN
TEXT
^
^Act II, Scene I - THE TEARS OF THE PROPHETS
^
^^ Sisko finds the ORB of the EMMISARY on the planet Tyree. He now knows he must
^^ re-enter the wormhole to seek the prohets (wormhole aliens) as he is the key to
^^ defeating the evil pah-wraiths. If he is not able to close the wormhole to prevent
^^ Dominion reinforcements from entering, all may be lost.
^
ENDTEXT
CREATEUNIT
unit=Trigger
owner=Dominion
veteran=no
homecity=None
locations
28,26
31,29
34,32
endlocations
PLAYWAVEFILE
ZORB.WAV
JUSTONCE
@ENDIF

@IF
UNITKILLED
unit=Trigger
attacker=ANYBODY
defender=Dominion
@THEN
PLAYWAVEFILE
INTRO.WAV
JUSTONCE
@ENDIF

@IF
UNITKILLED
unit=Trigger
attacker=ANYBODY
defender=Dominion
@THEN
TEXT
^
^Act II, Scene II - IN PURGATORY'S SHADOW
^
^^ Sisko enters the timeless realm of the wormhole aliens. He wages a mental battle
^^ with the Pah-Wraiths who try to convince him he is Benny Russell, a mental patient
^^ of the 1950s while he searches for Sarah, the prophet who was once his mother.
^
^^ A secondary dungeon type map is now open at the bottom right. This map will run
^^ concurrently with the main map.
^
ENDTEXT
CREATEUNIT
unit=Sisko
owner=Utd Fed of Planets
veteran=yes
homecity=None
locations
142,106
141,107
142,104
143,105
endlocations
PLAYWAVEFILE
ZCOME.WAV
JUSTONCE
@ENDIF

@IF
UNITKILLED
unit=Sarah
attacker=ANYBODY
defender=Dominion
@THEN
PLAYWAVEFILE
INTRO.WAV
JUSTONCE
@ENDIF

@IF
UNITKILLED
unit=Sarah
attacker=ANYBODY
defender=Dominion
@THEN
TEXT
^
^Act II, Scene III - A CALL TO ARMS
^
^^ The rebellion within the wormhole has been quelled. The wormhole is sealed and
^^ Dominion forces in the Gamma Quadrant are unable to travel to the Alpha Quadrant.
^
^^ Starfleet Command believes that an all-out assault on the Chin'toka system is the
^^ best option now. This will put the Dominion Alliance on the defensive before they
^^ can build new facilities in the Alpha Quadrant. (Disband Sisko Now)
^
ENDTEXT
CREATEUNIT
unit=Battleship
owner=Dominion
veteran=yes
homecity=None
locations
28,44
32,46
endlocations
PLAYWAVEFILE
ZSTOP.WAV
JUSTONCE
CHANGETERRAIN
terraintype=10
maprect
24,22,24,22,24,22,24,22
@ENDIF

@IF
UNITKILLED
unit=Sisko
attacker=ANYBODY
defender=Utd Fed of Planets
@THEN
TEXT
^
^Act II, Scene III - FAR BEYOND THE STARS
^
^^ The Pah-Wraiths finally overcome Sisko, take control of the celestial temple
^^ and guess what....they decide to keep the wormhole open. Sisko is lost somewhere
^^ in time and space and spends eternity as a lunatic writer trapped in an asylum.
^
^^ You may continue playing, but I suggest you start another game.
^
ENDTEXT
PLAYWAVEFILE
INTRO.WAV
JUSTONCE
@ENDIF

@IF
UNITKILLED
unit=OD Platform
attacker=ANYBODY
defender=ANYBODY
@THEN
TEXT
^
^^ Scans of debris from a destroyed Orbital Defense Platform indicate that they are
^^ powered via a remote subspace link. Our best bet is to find and destroy their
^^ central power source, probably a complex hidden on a nearby moon or asteroid.
^
ENDTEXT
JUSTONCE
@ENDIF

@IF
UNITKILLED
unit=Energy Base1
attacker=ANYBODY
defender=ANYBODY
@THEN
TEXT
^
^Act III, Scene I - SACRIFICE OF ANGELS
^
^^ After heavy losses, the Northern flank of the Chin'toka Orbital Defence Network
^^ is finally neutralized. Cardassians are greatly shaken by this unexpected defeat.
^
^^ Interrogation of prisoners reveals the presence of a huge Dominion shipyard
^^ facility in the vecinity of Monac IV that is mass producing War Cruisers.
^
ENDTEXT
CREATEUNIT
unit=Shipyard
owner=Dominion
veteran=yes
homecity=None
locations
28,44
32,46
endlocations
PLAYWAVEFILE
INTRO.WAV
JUSTONCE
CHANGETERRAIN
terraintype=2
maprect
56,62,64,62,66,64,56,66
@ENDIF

@IF
UNITKILLED
unit=Energy Base 2
attacker=ANYBODY
defender=ANYBODY
@THEN
TEXT
^
^Act III, Scene II - FAVOUR THE BOLD
^
^^ The Eastern flank of the Chin'toka Orbital Defence Network is finally neutralized
^^ This will allow the Klingons to mount direct assaults on the Cardassian heartland.
^^ Gowron is killed in a coup and Martok is the new Chancellor. He bets you twenty
^^ cases of bloodwine that he will be waiting for you on Cardassia Prime.
^
^^ Intelligence discovers that there is a major Cardassian shipyard facility orbiting
^^ the planet of Torros III
^
ENDTEXT
CREATEUNIT
unit=Shipyard
owner=Cardassian Union
veteran=yes
homecity=None
locations
57,97
55,103
endlocations
PLAYWAVEFILE
INTRO.WAV
JUSTONCE
CHANGETERRAIN
terraintype=2
maprect
64,66,66,66,66,80,64,80
@ENDIF

@IF
CITYTAKEN
city=Bajor
attacker=Utd Fed of Planets
defender=ANYBODY
@THEN
TEXT
^
^Act III, Scene III - RETURN TO GRACE
^
^^ Federation Forces return triupmhantly to Bajor. Gul Dukat is only interested
^^ in releasing all the incarcerated pah-wraiths and is no longer concerned
^^ with the war between mortals. Damar, his second-in-command becomes the
^^ new Cardassian leader, nominally under the control of the Dominion overseers.
^
ENDTEXT
PLAYWAVEFILE
INTRO.WAV
JUSTONCE
@ENDIF

@IF
CITYTAKEN
city=Chin'toka
attacker=ANYBODY
defender=Cardassian Union
@THEN
TEXT
^
^Act III, Scene IV - EXTREME MEASURES
^
^^ Chin'toka has fallen. Part of the planet's data network was found intact and 
^^ a target of opportunity, a Dominion Ketracel White production facility near 
^^ Palosa, was discovered.
^
^^ A desperate Cardassian High Command authorizes the reactivation of its Metagenic
^^ Weapons Program. When ready, the Cardassians will be able to deliver genetically
^^ engineered viruses using a theta band subspace carrier wave.
^
ENDTEXT
CREATEUNIT
unit=Facility
owner=Dominion
veteran=yes
homecity=None
locations
23,73
20,70
endlocations
PLAYWAVEFILE
INTRO.WAV
JUSTONCE
GIVETECHNOLOGY
receiver=Cardassian Union
technology=25
@ENDIF

@IF
TURN
turn=-1
@THEN
CREATEUNIT
unit=Galor
owner=Cardassian Union
veteran=no
homecity=None
locations
57,97
endlocations
@ENDIF

@IF
TURN
turn=-1
@THEN
CREATEUNIT
unit=War Cruiser
owner=Dominion
veteran=no
homecity=None
locations
28,44
endlocations
@ENDIF

@IF
UNITKILLED
unit=Shipyard
attacker=ANYBODY
defender=Cardassian Union
@THEN
TEXT
^
^Act IV, Scene I - THE DOGS OF WAR Part One
^
^^ The Cardassian Shipbuilding Facility near Torros III has been completely destroyed
^^ in a surprise attack. This has curtailed the production powers of the Cardassians
^^ severely.
^
^^ (The Cardies won't be getting a free Galor cruiser every turn anymore)
^
ENDTEXT
CREATEUNIT
unit=Metagenic Wepn
owner=Cardassian Union
veteran=yes
homecity=None
locations
52,92
endlocations
PLAYWAVEFILE
INTRO.WAV
JUSTONCE
CHANGETERRAIN
terraintype=10
maprect
57,97,57,97,57,97,57,97
GIVETECHNOLOGY
receiver=Cardassian Union
technology=58
@ENDIF

@IF
UNITKILLED
unit=Shipyard
attacker=ANYBODY
defender=Dominion
@THEN
TEXT
^
^Act IV, Scene II - THE DOGS OF WAR Part Two
^
^^ An asteroid orbiting Monac IV that was once the main Dominion shipbuilding
^^ facility in the Alpha Quadrant is now a rock of smouldering ruins.
^
^^ (The Dominion will no longer receive a free War Cruiser every turn.)
^
ENDTEXT
PLAYWAVEFILE
INTRO.WAV
JUSTONCE
CHANGETERRAIN
terraintype=10
maprect
28,44,28,44,28,44,28,44
GIVETECHNOLOGY
receiver=Dominion
technology=50
@ENDIF

@IF
UNITKILLED
unit=Facility
attacker=ANYBODY
defender=Dominion
@THEN
TEXT
^
^Act IV, Scene III - BY INFERNO'S LIGHT
^
^^ The Dominion ketracel-white facility near Palosa has been completely destroyed
^^ in a lightning raid. K-white is an enzyme that is required to keep all Jem'Hadar
^^ alive. Reduced production levels has made it much more difficult for the Dominion
^^ to maintain their army of Jem'Hadar warriors.
^
^^ (The Dominion's Attack Ships now cost twice as much)
^
ENDTEXT
MOVEUNIT
unit=Shield Cutter
owner=Breen Confederation
maprect
14,0,22,0,22,18,14,18
moveto
88,22
numbertomove=9
PLAYWAVEFILE
INTRO.WAV
JUSTONCE
CHANGETERRAIN
terraintype=2
maprect
26,14,30,14,30,18,26,18
GIVETECHNOLOGY
receiver=Dominion
technology=81
@ENDIF

@IF
UNITKILLED
unit=Facility
attacker=ANYBODY
defender=Dominion
@THEN
JUSTONCE
CHANGETERRAIN
terraintype=2
maprect
38,0,44,0,44,6,36,6
GIVETECHNOLOGY
receiver=Breen Confederation
technology=24
@ENDIF

@IF
UNITKILLED
unit=Shield Cutter
attacker=ANYBODY
defender=Breen Confederation
@THEN
TEXT
^
^Act IV, Scene IV - THE CHANGING FACE OF EVIL
^
^^ Against all expectations, the Dominion have managed to forge a new alliance with
^^ the Breen, a reclusive race which lives in artic conditions. The Cardassians were
^^ after all disappointing partners. One of the features of Breen technology is the
^^ devestating ability to disable the shields of other ships using a "Shield Cutter" 
^^ beam weapon. We must find their artic homeworld and destroy them.
^
ENDTEXT
MOVEUNIT
unit=Shield Cutter
owner=Breen Confederation
maprect
24,0,38,0,38,18,24,18
moveto
73,27
numbertomove=9
PLAYWAVEFILE
INTRO.WAV
JUSTONCE
@ENDIF

@IF
CITYTAKEN
city=Cardassia
attacker=ANYBODY
defender=Cardassian Union
@THEN
TEXT
^
^Act V, Scene I - BLAZE OF GLORY
^
^^ After a long siege, Allied troops finally land on Cadassia and the capital
^^ Cardassia Prime is occupied. Damar overcame his drinking problem and in the final
^^ days instigated a rebellion against the Founder overlords. The impotent remnants
^^ of the Cardassian Union can be largely igonored from now on and we should concentrate
^^ our attacks on the Dominion.
^
ENDTEXT
CREATEUNIT
unit=Dukat
owner=Dominion
veteran=no
homecity=None
locations
148,2
endlocations
PLAYWAVEFILE
INTRO.WAV
JUSTONCE
GIVETECHNOLOGY
receiver=Cardassian Union
technology=91
@ENDIF

@IF
CITYTAKEN
city=Breen
attacker=ANYBODY
defender=Breen Confederation
@THEN
TEXT
^
^Act V, Scene II - ONCE MORE UNTO THE BREACH
^
^^ The Breen put up a good fight but the forces of the Federation have prevailed 
^^ even on the cryogenic environment of the Breen Homeworld. They now perpare for 
^^ the invasion of the Founder's homeworld.
^
^^ At the same time Sisko tracks Gul Dukat into the Fire Caves of Bajor where he is
^^ performing a ritual to release the imprisoned pah-wraiths. He must stop the
^^ maniac before it is too late.
^
ENDTEXT
CREATEUNIT
unit=Sisko2
owner=Utd Fed of Planets
veteran=yes
homecity=None
locations
142,20
142,6
endlocations
PLAYWAVEFILE
INTRO.WAV
JUSTONCE
@ENDIF

@IF
UNITKILLED
unit=Dukat
attacker=Utd Fed of Planets
defender=Dominion
@THEN
TEXT
^
^Act V, Scene II - THE MEASURE OF A MAN
^
^^ Sisko sacrifices himself by dragging Gul Dukat into a firey abyss thereby killing
^^ the last free pah-wraith. He ascends to the celestial temple as an energy entity.
^^ The prophets, sensing that Bajor is no longer in danger, relinquish their control
^^ of the wormhole. Finish off the Dominion and its Founders.
^
ENDTEXT
PLAYWAVEFILE
ZCOME.WAV
JUSTONCE
CHANGETERRAIN
terraintype=2
maprect
24,22,24,22,24,22,24,22
@ENDIF

@IF
CITYTAKEN
city=Great Link
attacker=ANYBODY
defender=Dominion
@THEN
TEXT
^
^Act V, Scene IV - TIL DEATH US DO PART
^
^^ Conflict effectively comes to an end as all life on the Founder's homeworld is
^^ extinguished by bombardment from orbit. As it would be impossible to invade a
^^ planet of changelings, it was decided that this was the only way.
^
^^ Well done. Kobayashi thanks you for playing
^
^^ STAR TREK : DOMINION WAR
^
ENDTEXT
PLAYWAVEFILE
ZNIGHT.WAV
JUSTONCE
DESTROYACIVILIZATION
whom=Dominion
@ENDIF

@IF
RECEIVEDTECHNOLOGY
technology=16
receiver=Utd Fed of Planets
@THEN
TEXT
^
^^ The first operational SOVEREIGN class starship - U.S.S. Enterprise is launched
^^ from the San Francisco Yards orbiting Earth. 24 decks tall and at over 700 meters
^^ in length, she is the Federation's best hope for victory. Production of Galaxy
^^ cruisers will cease.
^
^^ Sovereign class cruisers have powerful shields which allow maximum warp in spite
^^ of stellar interference and upgraded sensor arrays which allow 2 space visibility.
^
ENDTEXT
CREATEUNIT
unit=Sovereign
owner=Utd Fed of Planets
veteran=no
homecity=None
locations
88,20
90,22
endlocations
PLAYWAVEFILE
ZWARP.WAV
JUSTONCE
@ENDIF

@IF
RECEIVEDTECHNOLOGY
technology=40
receiver=Utd Fed of Planets
@THEN
TEXT
^
^^ The first operational NORWAY class starship - U.S.S. Budapest is launched from
^^ the Earth Station McKinley. Federation yards will cease production of Ambassador
^^ class cruisers in favour of the new Norway class cruisers.
^
^^ Norway class cruisers have powerful sensor arrays which allow two space visibility.
^
ENDTEXT
CREATEUNIT
unit=Norway
owner=Utd Fed of Planets
veteran=no
homecity=None
locations
88,20
90,22
endlocations
PLAYWAVEFILE
ZWARP.WAV
JUSTONCE
@ENDIF

@IF
RECEIVEDTECHNOLOGY
technology=61
receiver=Utd Fed of Planets
@THEN
TEXT
^
^^ After continued upgrades of the Excelsior over the decades, now over half a
^^ century since NX-2000 was first used as the transwarp testbed, the workhorse of
^^ Starfleet is finally being retired. Its replacement is the first of a new catamarran
^^ series of starship designs, the STEAMRUNNER class. The U.S.S. Appalachia is
^^ commissioned at the Antares Shipyards.
^
^^ Steamrunner class planetary defense cruisers are agile enough to avoid zones of
^^ control and can fire on small attack craft.
^
ENDTEXT
CREATEUNIT
unit=Steamrunner
owner=Utd Fed of Planets
veteran=no
homecity=None
locations
88,20
90,22
endlocations
PLAYWAVEFILE
ZWARP.WAV
JUSTONCE
@ENDIF

@IF
RECEIVEDTECHNOLOGY
technology=10
receiver=Utd Fed of Planets
@THEN
TEXT
^
^^ The compact Miranda design, and its upgraded variant the Soyuz class is now over
^^ 80 years old. They will finally be phased out as the SABRE class starships are
^^ introduced. Fulfilling the escourt role, U.S.S. Yeager is launched from Earth's
^^ San Francisco Yards.
^
^^ Sabre class ships pack a heavy punch for their small size but are nimble enough
^^ to avoid zones of control and their superb agility gives them the ability to fire
^^ on and receive a defense bonus against small attack craft.
^
ENDTEXT
CREATEUNIT
unit=Sabre
owner=Utd Fed of Planets
veteran=no
homecity=None
locations
88,20
90,22
endlocations
PLAYWAVEFILE
ZWARP.WAV
JUSTONCE
@ENDIF

@IF
RECEIVEDTECHNOLOGY
technology=71
receiver=Utd Fed of Planets
@THEN
TEXT
^
^^ The first operational AKIRA class starship - U.S.S. Thunderchild is launched from
^^ the Utopia Planetia Yards orbiting Mars. These state of the art cruisers will begin
^^ to replace existing Nebula cruisers which were carrying planetary assault modules.
^
^^ Akira class cruisers have been designed with multiple hanger bays for assault shuttles
^^ and tactical fighters and extensive facilities for planetary assault troops.
^
ENDTEXT
CREATEUNIT
unit=Akira
owner=Utd Fed of Planets
veteran=no
homecity=None
locations
88,20
90,22
endlocations
PLAYWAVEFILE
ZWARP.WAV
JUSTONCE
@ENDIF

@IF
RECEIVEDTECHNOLOGY
technology=73
receiver=Utd Fed of Planets
@THEN
TEXT
^
^^ The Intrepid class starship - U.S.S. Voyager is commissioned at the Utopia
^^ Planetia Yards orbiting Mars. These new cruisers, sporting neural gel-packs,
^^ will be used in the exploration role.
^
^^ Well armed and shielded, they are suited for a limited combat role while their
^^ extensive sensor suite still allows them to act as science vessels.
^
ENDTEXT
CREATEUNIT
unit=Intrepid
owner=Utd Fed of Planets
veteran=no
homecity=None
locations
88,20
90,22
endlocations
PLAYWAVEFILE
ZWARP.WAV
JUSTONCE
@ENDIF

@IF
TURN
turn=48
@THEN
TEXT
^
^^ Starfleet Intelligence has spotted several modified Cardassian Galor class ships,
^^ codenamed Keldon type cruisers. These cruisers have upgraded engines and an
^^ auxillary weapons module retro-fitted onto the dorsal section.
^
ENDTEXT
JUSTONCE
GIVETECHNOLOGY
receiver=Cardassian Union
technology=44
@ENDIF

@IF
TURN
turn=65
@THEN
GIVETECHNOLOGY
receiver=Romulan Star Empire
technology=11
@ENDIF

@IF
TURN
turn=45
@THEN
GIVETECHNOLOGY
receiver=Imperial Klingon Empire
technology=23
@ENDIF

@IF
TURN
turn=30
@THEN
TEXT
^
^^ Klingon High Command has informed us that they are re-activating their mothballed
^^ K'Tinga Fleet, and using them as tri-cobalt armed kamikazi cruisers.
^
ENDTEXT
GIVETECHNOLOGY
receiver=Imperial Klingon Empire
technology=6
@ENDIF

@IF
CITYTAKEN
city=Torna IV
attacker=Cardassian Union
defender=Imperial Klingon Empire
@THEN
TEXT
^
^MESSAGE FROM GENERAL MARTOK
^
^^ The Cardassian dogs are deep in Klingon territory. If you do not send a fleet to
^^ help us, the treacherous Romulans may sense an opportunity and turn on us. Q'ap'La.
^
ENDTEXT
GIVETECHNOLOGY
receiver=Imperial Klingon Empire
technology=34
@ENDIF

@IF
UNITKILLED
unit=Defiant
attacker=ANYBODY
defender=Utd Fed of Planets
@THEN
TEXT
^
^MESSAGE FROM STARFLEET COMMAND
^
^^ Heard you lost your Defiant. We happen to have another left over from the test
^^ program. Its our last one, so don't lose it!
^
ENDTEXT
CREATEUNIT
unit=Defiant
owner=Utd Fed of Planets
veteran=no
homecity=None
locations
88,20
90,22
endlocations
JUSTONCE
@ENDIF

@IF
UNITKILLED
unit=Neg'var
attacker=Cardassian Union
defender=Imperial Klingon Empire
@THEN
CREATEUNIT
unit=Vor'cha
owner=Imperial Klingon Empire
veteran=no
homecity=None
locations
115,79
endlocations
@ENDIF

@IF
CITYTAKEN
city=Bajor
attacker=Cardassian Union
defender=Utd Fed of Planets
@THEN
CREATEUNIT
unit=Shields
owner=Cardassian Union
veteran=yes
homecity=None
locations
49,53
endlocations
JUSTONCE
@ENDIF

@IF
CITYTAKEN
city=Bajor
attacker=Dominion
defender=Utd Fed of Planets
@THEN
CREATEUNIT
unit=Shields
owner=Dominion
veteran=yes
homecity=None
locations
49,53
endlocations
JUSTONCE
@ENDIF

@IF
UNITKILLED
unit=Ambassador
attacker=Dominion
defender=Utd Fed of Planets
@THEN
CREATEUNIT
unit=War Cruiser
owner=Dominion
veteran=no
homecity=None
locations
49,3
endlocations
@ENDIF

@IF
UNITKILLED
unit=Ambassador
attacker=Cardassian Union
defender=Utd Fed of Planets
@THEN
CREATEUNIT
unit=War Cruiser
owner=Dominion
veteran=no
homecity=None
locations
49,3
endlocations
@ENDIF

@IF
CITYTAKEN
city=Yridia
attacker=ANYBODY
defender=Cardassian Union
@THEN
TEXT
^
^^ The Yridia section of the Cardassian Orbital Defence Network is
^^ now inoperational with the capitulation of the planet.
^
ENDTEXT
JUSTONCE
CHANGETERRAIN
terraintype=2
maprect
63,93,65,93,65,105,63,105
@ENDIF

@IF
TURN
turn=1
@THEN
CHANGETERRAIN
terraintype=10
maprect
138,0,148,0,148,24,138,24
@ENDIF

@IF
TURN
turn=2
@THEN
CHANGETERRAIN
terraintype=8
maprect
140,0,148,0,148,22,140,22
@ENDIF

@IF
TURN
turn=3
@THEN
CHANGETERRAIN
terraintype=10
maprect
144,6,146,6,146,16,144,14
@ENDIF

@IF
RECEIVEDTECHNOLOGY
technology=91
receiver=Cardassian Union
@THEN
MAKEAGGRESSION
who=Cardassian Union
whom=Dominion
@ENDIF

@ENDEVENTS
