;
; Events text for Exodus 1947 Scenario
; Copyright(c) 1999, Alexandre Ostrowiecki
;
;

@BEGINEVENTS

@IF
NOSCHISM
defender=ANYBODY
@THEN
@ENDIF

@IF
NEGOTIATION
talker=ANYBODY
talkertype=HumanOrComputer
listener=ANYBODY
listenertype=HumanOrComputer
@THEN
@ENDIF

@IF
SCENARIOLOADED
@THEN
PLAYWAVEFILE
ISRAEL.WAV
@ENDIF

@IF
TURN
turn=1
@THEN
TEXT
The date is November 29th, 1947. Right now, in the General Assembly, a decisive vote is taking 
place. Each nation of the world puts forth its representative to choose for or against the partition 
of Palestine in two states, one Arab and one Jewish. The Jews of Palestine, after 2.000 years 
without a homeland, accepted the plan, while the Arabs rejected it, claiming that they should 
keep all of the land. Furthermore, the Arabs threatened to attack the Jews should they declare a 
state. One by one, the representatives of all of the nations of the world cast their votes: 
Brazil... in favor. United Kindom... abstained. Saudi Arabia... against. United States of 
America... in favor. In the end, the plan was accepted by a majority of two thirds and a deadline 
was established for the British to leave Palestine and the two states be created: MAY 14th, 
1948.
ENDTEXT
@ENDIF

@IF
TURN
turn=-1
@THEN
TEXT
New jewish imigrants arrive in the refugee camps. Some are survivors of the holocaust who 
arrived in Caraolos, Cyprus. Others are Iemenite jews who desire to reach Eretz Israel. They can 
only emigrate to Palestine after the creation of Israel. Before then, they are forbiden by the 
British, who have established imigration quotas for jews.
ENDTEXT
CREATEUNIT
unit=Imigrant
owner=Israelis
veteran=no
homecity=None
locations
2,16
0,0
0,0
endlocations
@ENDIF

@IF
TURN
turn=-1
@THEN
CREATEUNIT
unit=Imigrant
owner=Israelis
veteran=no
homecity=None
locations
68,196
endlocations
@ENDIF

@IF
UNITKILLED
unit=Armored Car $
attacker=Israelis
defender=ANYBODY
@THEN
TEXT
Newly purchased armored cars have just arrived in the Lod airport near Tel Aviv. COST  $300
ENDTEXT
CREATEUNIT
unit=Armored Car
owner=Israelis
veteran=no
homecity=None
locations
45,69
endlocations
CHANGEMONEY
receiver=Israelis
amount=-300
@ENDIF

@IF
UNITKILLED
unit=T-34 $
attacker=Israelis
defender=ANYBODY
@THEN
TEXT
Newly purchased T-34 tanks have just arrived in the Lod airport near Tel Aviv. COST $500
ENDTEXT
CREATEUNIT
unit=T-34
owner=Israelis
veteran=no
homecity=None
locations
45,69
endlocations
CHANGEMONEY
receiver=Israelis
amount=-500
@ENDIF

@IF
UNITKILLED
unit=Artilery $
attacker=Israelis
defender=ANYBODY
@THEN
TEXT
Newly purchased artillery pieces have just arrived in the Lod airport near Tel Aviv. COST $150
ENDTEXT
CREATEUNIT
unit=WWII Artillery
owner=Israelis
veteran=no
homecity=None
locations
45,69
endlocations
CHANGEMONEY
receiver=Israelis
amount=-150
@ENDIF

@IF
UNITKILLED
unit=Spitfire $
attacker=Israelis
defender=ANYBODY
@THEN
TEXT
Newly purchased Spitfire aircraft have just arrived in the Lod airport near Tel Aviv. COST $600
ENDTEXT
CREATEUNIT
unit=Spitfire
owner=Israelis
veteran=no
homecity=None
locations
45,69
0,0
endlocations
CHANGEMONEY
receiver=Israelis
amount=-600
@ENDIF

@IF
UNITKILLED
unit=B-17 $
attacker=Israelis
defender=ANYBODY
@THEN
TEXT
Newly purchased B-17 Bombers have just arrived in the Lod airport near Tel Aviv. COST $600
ENDTEXT
CREATEUNIT
unit=B-17 Bomber
owner=Israelis
veteran=no
homecity=None
locations
45,69
endlocations
CHANGEMONEY
receiver=Israelis
amount=-600
@ENDIF

@IF
UNITKILLED
unit=B-29 $
attacker=Israelis
defender=ANYBODY
@THEN
TEXT
Newly purchased B-29 Bombers have just arrived in the Lod airport near Tel Aviv. COST $900
ENDTEXT
CREATEUNIT
unit=B-29 Bomber
owner=Israelis
veteran=no
homecity=None
locations
45,69
endlocations
CHANGEMONEY
receiver=Israelis
amount=-900
@ENDIF

@IF
UNITKILLED
unit=Messershmidt $
attacker=Israelis
defender=ANYBODY
@THEN
TEXT
Newly purchased ME fighters have just arrived in the Lod airport near Tel Aviv. COST $400
ENDTEXT
CREATEUNIT
unit=Avia S-99
owner=Israelis
veteran=no
homecity=None
locations
45,69
endlocations
CHANGEMONEY
receiver=Israelis
amount=-400
@ENDIF

@IF
UNITKILLED
unit=Cruiser $
attacker=Israelis
defender=ANYBODY
@THEN
TEXT
Newly purchased Cruiser vessels have just arrived in the port of Haifa. COST $400
ENDTEXT
CREATEUNIT
unit=Cruiser
owner=Israelis
veteran=no
homecity=None
locations
43,39
endlocations
CHANGEMONEY
receiver=Israelis
amount=-400
@ENDIF

@IF
RANDOMTURN
denominator=6
@THEN
TEXT
The Keren Hayessod emissar returns to Israel with funds donated by jewish comunities abroad.  
($3.000)
ENDTEXT
CHANGEMONEY
receiver=Israelis
amount=3000
@ENDIF

@IF
TURN
turn=3
@THEN
TEXT
The deadline is MAY 14th 1948. In this day, the last of the British soldiers will leave Palestine. 
The future is uncertain. Will the neighbouring arab nations strike? Right now, the situation is 
serious. A civil war occurs between the jews and arabs of palestine. Jerusalem is blocked and the 
last convoys sent to its relief were destroyed by the arab forces. What will happen if foreign 
armies also intervene against the jews?
ENDTEXT
@ENDIF

@IF
TURN
turn=5
@THEN
TEXT
"Soon the deadline will be reached and the british will leave this land. On one side, this is good 
news, for weīll be able to declare Israelīs independence and start building our country. 
Imigration, agriculture, science... thereīs so much to do. On the other hand, we fear that the 
armies of our Arab neighbours will attack us. To the north, lies Lebanon and Syria. They controll 
the hights and can strike at our colonies in the Hula valley. To the south, powerfull Egypt. Their 
armored cars can strike and reach Tel Aviv and the other coastal cities. Finally, to the east, 
Jordanians, with their infamous Arab legion. They are the greatest threat to Jerusalem"
ENDTEXT
@ENDIF

@IF
TURN
turn=7
@THEN
TEXT
May 14th 1948. The last of the British troops leave Eretz Israel. In Tel Aviv, David Ben Gurion 
declares the independence of Israel. After 2.000 years, the jews once more have a homeland and 
can be free citizens in their own state. People in the streets cheer and dance, while a provisional 
government is formed until the first elections. Unfortunatelly, the happyness is short lived. On the 
same day, the armies of  5 arab nations cross the borders and prepare to destroy the new born 
state and "throw the jews back to the sea".
ENDTEXT
PLAYWAVEFILE
ISRAEL.WAV
DESTROYACIVILIZATION
whom=British Mandate
@ENDIF

@IF
TURN
turn=7
@THEN
TEXT
After the departure of the British, the new Israeli state imediatelly prepares for the absortion of 
thousands of refugees, both from Europe and from the Arab countries. Also, Israel is free to 
import arms for itīs ongoing war. Shimon Perez is sent to by weapons in Europe.
ENDTEXT
CREATEUNIT
unit=Shimon Peres
owner=Israelis
veteran=yes
homecity=None
locations
2,2
endlocations
@ENDIF

@IF
TURN
turn=-1
@THEN
CHANGEMONEY
receiver=Jordanians
amount=300
@ENDIF

@IF
TURN
turn=-1
@THEN
CHANGEMONEY
receiver=Egyptians
amount=800
@ENDIF

@IF
TURN
turn=-1
@THEN
CHANGEMONEY
receiver=Sirians
amount=500
@ENDIF

@IF
TURNINTERVAL
interval=2
@THEN
MOVEUNIT
unit=ANYUNIT
owner=Lebanese
maprect
40,0,58,0,58,24,40,24
moveto
43,39
numbertomove=ALL
@ENDIF

@IF
TURNINTERVAL
interval=2
@THEN
MOVEUNIT
unit=ANYUNIT
owner=Sirians
maprect
60,0,84,0,84,32,60,32
moveto
43,39
numbertomove=ALL
@ENDIF

@IF
TURNINTERVAL
interval=2
@THEN
MOVEUNIT
unit=ANYUNIT
owner=Egyptians
maprect
2,84,42,84,42,134,2,134
moveto
45,69
numbertomove=ALL
@ENDIF

@IF
TURNINTERVAL
interval=2
@THEN
CREATEUNIT
unit=Kibutznick
owner=Israelis
veteran=yes
homecity=NONE
locations
68,196
endlocations
@ENDIF

@IF
TURNINTERVAL
interval=2
@THEN
CREATEUNIT
unit=Zion Worker
owner=Israelis
veteran=yes
homecity=NONE
locations
2,16
endlocations
@ENDIF

@IF
UNITKILLED
unit=Har El Brigade
attacker=ANYBODY
defender=Israelis
@THEN
TEXT
The Har El Brigade, under the comand of Itzhack Rabin, has been severelly attacked. The unit 
returns to Tel Aviv for refit.
ENDTEXT
CREATEUNIT
unit=Har El Brigade
owner=Israelis
veteran=yes
homecity=None
locations
42,68
42,69
43,68
44,68
endlocations
JUSTONCE
@ENDIF

@IF
UNITKILLED
unit=Ben Gurion
attacker=ANYBODY
defender=Israelis
@THEN
TEXT
David Ben Gurion, first Prime Minister of Israel, returns from the front concerned. The situation is 
tense. 
ENDTEXT
CREATEUNIT
unit=Ben Gurion
owner=Israelis
veteran=yes
homecity=None
locations
42,68
42,69
43,68
43,69
endlocations
JUSTONCE
@ENDIF

@IF
TURN
turn=2
@THEN
TEXT
Military report of Ygal Allon, commander of the israeli forces: "We are facing dificult times 
ahead. Jerusalem is under siege and most of our cities in the north are isolated from the coast. It 
is imperative that we free the road to Jerusalem and to the Kibutzim in the Hula valley near the 
Syrian border. In this sense, we have decided to split the forces in two groups. The first one, the 
Har El Brigade, will operate in the Jerusalem area and will be headed by  Itzhack Rabin. Itīs 
objective will be either to free the road or to build a new one, using the Kibutznickim. The 
northern group will be ordered to strike at Safed, the mountain bastion, Tiberias and Nazareth. 
This operation will be able to keep an open and vital line from Tel Aviv, in the coast to the 
northernmost settlements at the border."
ENDTEXT
CREATEUNIT
unit=Har El Brigade
owner=Israelis
veteran=yes
homecity=None
locations
42,68
endlocations
@ENDIF

@IF
RANDOMTURN
denominator=2
@THEN
CREATEUNIT
unit=B-17 Bomber
owner=Egyptians
veteran=no
homecity=None
locations
6,132
endlocations
@ENDIF

@IF
RANDOMTURN
denominator=2
@THEN
CREATEUNIT
unit=Avia S-99
owner=Egyptians
veteran=no
homecity=None
locations
6,132
endlocations
@ENDIF

@IF
RANDOMTURN
denominator=3
@THEN
CREATEUNIT
unit=Avia S-99
owner=Sirians
veteran=no
homecity=None
locations
73,3
endlocations
@ENDIF

@IF
RANDOMTURN
denominator=3
@THEN
CREATEUNIT
unit=B-17 Bomber
owner=Sirians
veteran=no
homecity=None
locations
73,3
endlocations
@ENDIF

@ENDEVENTS
